dev-python/python-dotenv: Address collision with dev-ruby/dotenv

I'm using a second entrypoint here rather than a plain rename
to not break (1) the tests and (2) access to argv[0] by python-exec.
Closes: https://bugs.gentoo.org/798648
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.19, Repoman-3.0.3

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild b/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild
new file mode 100644
index 000000000000..aa3667814def
--- /dev/null
+++ b/dev-python/python-dotenv/python-dotenv-0.18.0-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="Manage .env files"
+HOMEPAGE="https://github.com/theskumar/python-dotenv"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~sparc ~x86"
+
+DEPEND="
+	test? (
+		>=dev-python/click-5[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		>=dev-python/sh-1.09[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( CHANGELOG.md README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.18.0-second-entrypoint.patch  # bug 798648
+)
+
+distutils_enable_tests --install pytest
+
+src_install() {
+	distutils-r1_src_install
+
+	# Avoid collision with dev-ruby/dotenv (bug #798648)
+	rm "${D}"/usr/bin/dotenv || die
+}