dev-python/python-language-server: version bump 0.31.9

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 65 insertions, 0 deletions

diff --git a/dev-python/python-language-server/python-language-server-0.31.9.ebuild b/dev-python/python-language-server/python-language-server-0.31.9.ebuild
new file mode 100644
index 000000000000..53b3086f0cdd
--- /dev/null
+++ b/dev-python/python-language-server/python-language-server-0.31.9.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit eutils distutils-r1
+
+DESCRIPTION="An implementation of the Language Server Protocol for Python"
+HOMEPAGE="https://github.com/palantir/python-language-server"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="dev-python/versioneer[${PYTHON_USEDEP}]"
+
+RDEPEND="
+	>=dev-python/jedi-0.14.1[${PYTHON_USEDEP}]
+	<dev-python/jedi-0.16.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	>=dev-python/python-jsonrpc-server-0.3.2[${PYTHON_USEDEP}]
+	<=dev-python/ujson-1.35[${PYTHON_USEDEP}]"
+
+DEPEND="test? (
+	dev-python/autopep8[${PYTHON_USEDEP}]
+	dev-python/flake8[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/mccabe[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/pycodestyle[${PYTHON_USEDEP}]
+	dev-python/pydocstyle[${PYTHON_USEDEP}]
+	dev-python/pyflakes[${PYTHON_USEDEP}]
+	dev-python/pylint[${PYTHON_USEDEP}]
+	dev-python/QtPy[testlib,${PYTHON_USEDEP}]
+	dev-python/rope[${PYTHON_USEDEP}]
+	dev-python/yapf[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dependencie
+	sed -i -e '16,18d' setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	elog "To get additional features, optional runtime dependencies may be installed:"
+	optfeature "Automatically formats Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}