dev-python/python-magic: add Python 3.7, PyPy{,3}, fix tests.

* Tests didn't work with recent versions of file. Provide patches that
  have been merged upstream.
* Fix dependencies, DEPEND=${DEPEND} was a typo.
* EAPI=7.

Package-Manager: Portage-2.3.45, Repoman-2.3.10
Closes: https://github.com/gentoo/gentoo/pull/9607

1 files changed, 37 insertions, 0 deletions

diff --git a/dev-python/python-magic/python-magic-0.4.15-r1.ebuild b/dev-python/python-magic/python-magic-0.4.15-r1.ebuild
new file mode 100644
index 000000000000..5a23238beb2f
--- /dev/null
+++ b/dev-python/python-magic/python-magic-0.4.15-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Access the libmagic file type identification library"
+HOMEPAGE="https://github.com/ahupp/python-magic"
+# https://github.com/ahupp/python-magic/pull/178
+SRC_URI="https://github.com/ahupp/python-magic/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~x86"
+IUSE="test"
+
+RDEPEND="sys-apps/file[-python]"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND} )
+"
+
+PATCHES=(
+	# https://github.com/ahupp/python-magic/pull/177
+	"${FILESDIR}/${P}-fix-buffer-test.patch"
+	# https://github.com/ahupp/python-magic/pull/176
+	"${FILESDIR}/${P}-fix-gzip-test.patch"
+	# https://github.com/ahupp/python-magic/commit/4bda684f8b461cc1f69593799efcf6afe8397756
+	"${FILESDIR}/${P}-fix-jpeg-test.patch"
+)
+
+python_test() {
+	"${EPYTHON}" test/test.py -v || die "Tests fail with ${EPYTHON}"
+}