dev-python/python-neutronclient: add 8.2.0, PEP517

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-python/python-neutronclient/Manifest b/dev-python/python-neutronclient/Manifest
index 92b1aef98611..db424627c514 100644
--- a/dev-python/python-neutronclient/Manifest
+++ b/dev-python/python-neutronclient/Manifest
@@ -1 +1,2 @@
 DIST python-neutronclient-8.1.0.tar.gz 304482 BLAKE2B c68426197913b8159efc590b0e4db4d9ac7abf7f3dba197d7f429b1fd489f7b545ba674a6acb3a395f529ec0a0009c06b8dea892f6c7895ec23d7172bf14c294 SHA512 d6c735c9a5ff0af1f3187d6cf46221138cb2f1dc3df2260aa9a7d10b0668137efa29d2e3cb6e2169b2d0801e03f6161aa08c0d499d9c9eae86fc8a1d32697e26
+DIST python-neutronclient-8.2.0.tar.gz 305020 BLAKE2B dd09015fcc91028300c4185f208a7d532734c3b4ce1a616855eda6a25afb73be620548301ba7e42144a9ce33983c7966818f43f5cbbfbb8695b61c837d89831f SHA512 b8ff0b143bd4f8d99c5e8778e6669a80231f81dc353674a1d9964df53db9b49a0347d613f9d9c13b8e8ac355d2b50795cc27712cab2d798963ae0e8d5e4a5564
diff --git a/dev-python/python-neutronclient/python-neutronclient-8.2.0.ebuild b/dev-python/python-neutronclient/python-neutronclient-8.2.0.ebuild
new file mode 100644
index 000000000000..11bb470a36ef
--- /dev/null
+++ b/dev-python/python-neutronclient/python-neutronclient-8.2.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="https://launchpad.net/neutron"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/os-client-config-1.28.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.5.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bandit[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/oslotest[${PYTHON_USEDEP}]
+		dev-python/python-openstackclient[${PYTHON_USEDEP}]
+		dev-python/subunit[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Needs osprofile
+	rm neutronclient/tests/unit/test_http.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b neutronclient.tests.unit
+}
+
+python_install() {
+	distutils-r1_python_install
+	# stupid stupid stupid
+	local SITEDIR="${D}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.dist-info )
+	[[ -d ${egg[0]} ]] || die "python_quantumclient*.dist-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}