dev-python/python-redmine: new version 2.0.2.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/python-redmine/python-redmine-2.0.2.ebuild b/dev-python/python-redmine/python-redmine-2.0.2.ebuild
new file mode 100644
index 000000000000..53c1001ea04d
--- /dev/null
+++ b/dev-python/python-redmine/python-redmine-2.0.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to the Redmine REST API"
+HOMEPAGE="https://github.com/maxtepkeev/python-redmine"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/requests[${PYTHON_USEDEP}]"
+
+# This package bundles dev-python/requests, so setup.py won't check for
+# it. As a result, we don't need RDEPEND in DEPEND unconditionally.
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/coverage[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Remove the bundled copy of dev-python/requests...
+	rm -r redminelib/packages/requests \
+		|| die 'failed to remove the bundled copy of dev-python/requests'
+
+	# and replace its local import statement with a global one.
+	sed -i redminelib/packages/__init__.py \
+		-e 's/from . import requests/import requests/' \
+		|| die 'failed to replace the dev-python/requests library import'
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests || die "tests failed under ${EPYTHON}"
+}