dev-python/python-tests: Add 3.11.9999 live ebuild

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-python/python-tests/python-tests-3.11.9999.ebuild b/dev-python/python-tests/python-tests-3.11.9999.ebuild
new file mode 100644
index 000000000000..234b8fd94f40
--- /dev/null
+++ b/dev-python/python-tests/python-tests-3.11.9999.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_11 )
+
+inherit git-r3 python-r1
+
+PYVER=$(ver_cut 1-2)
+PATCHSET="python-gentoo-patches-3.11.11"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+EGIT_REPO_URI="https://github.com/python/cpython.git"
+EGIT_BRANCH=${PYVER}
+S="${WORKDIR}/${P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+# enable by default to help CI handle it (we have no additional deps)
+IUSE="+python_targets_${PYTHON_COMPAT[0]}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+	!<dev-lang/python-3.11.9_p2-r1:${PYVER}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+src_unpack() {
+	git-r3_src_unpack
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	local dirs=(
+		ctypes/test distutils/tests idlelib/idle_test lib2to3/tests
+		./test tkinter/test unittest/test
+	)
+	local dir
+	for dir in "${dirs[@]}"; do
+		python_moduleinto "/usr/lib/python${PYVER}/${dir%/*}"
+		python_domodule "${dir}"
+	done
+}