dev-python/qscintilla-python: add 2.11.1, drop python3_4 support

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

1 files changed, 72 insertions, 0 deletions

diff --git a/dev-python/qscintilla-python/qscintilla-python-2.11.1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.11.1.ebuild
new file mode 100644
index 000000000000..dfe6ef7c314a
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.11.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit python-r1 qmake-utils
+
+MY_P=QScintilla_gpl-${PV/_pre/.dev}
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
+SRC_URI="https://www.riverbankcomputing.com/static/Downloads/QScintilla/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.19:=[${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_prepare() {
+	default
+	python_copy_sources
+}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			configure.py
+			--pyqt=PyQt5
+			--qmake="$(qt5_get_bindir)"/qmake
+			--sip-incdir="$(python_get_includedir)"
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain, build flags, and prevent stripping
+		eqmake5 -recursive
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		# parallel install fails because mk_distinfo.py runs too early
+		emake -j1 INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}