Rename dev-python/{setuptools_scm → setuptools-scm}

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-python/setuptools-scm/setuptools-scm-7.1.0.ebuild b/dev-python/setuptools-scm/setuptools-scm-7.1.0.ebuild
new file mode 100644
index 000000000000..87fa9e5896d7
--- /dev/null
+++ b/dev-python/setuptools-scm/setuptools-scm-7.1.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Manage versions by scm tags via setuptools"
+HOMEPAGE="
+	https://github.com/pypa/setuptools_scm/
+	https://pypi.org/project/setuptools-scm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{8..10})
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-vcs/git
+		!sparc? (
+			dev-vcs/mercurial
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# the usual nondescript gpg-agent failure
+		testing/test_git.py::test_git_getdate_signed_commit
+
+		# fetching from the Internet
+		testing/test_regressions.py::test_pip_download
+	)
+
+	if has_version dev-python/nose; then
+		EPYTEST_DESELECT+=(
+			# https://bugs.gentoo.org/892639
+			testing/test_integration.py::test_pyproject_support
+		)
+	fi
+
+	epytest
+}