dev-python/scikit-learn: Bump to 1.5.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index c5d0c26e1a8b..e49bdf20e2a3 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1 +1,2 @@
 DIST scikit-learn-1.5.1.gh.tar.gz 6944196 BLAKE2B 65ed2016e1caf12e9a347e133b6b3be29b234de7ee8e374859a7235da3ede67a1b4c37a253b62ceb85a1ae3a1e6bc5afea2a0f07f4a7c81f59965614bde52b8c SHA512 f04c988490436d46d8210e68e41969af689810eff3e57098694768d3ccb7c4b919aecb13f36af1534745e56785fbf55c3dc3614497765d5b2f7c5e7e8dfbae05
+DIST scikit-learn-1.5.2.gh.tar.gz 6982418 BLAKE2B f1fdc37cdbc7625f5240b565b37b8213e1f6a21cb04886efaa2f9dad598eaa3c9bf567000cb51bcb78057172131ab3534134bb7382ed0b1df5037919d45fd65e SHA512 ed014858a9dd75765b761df03782048035228f012773d70ca3355d049d096707286b8b3d0139b88268266e8f0a6b4d430968495a87636975d094b161b9f0d712
diff --git a/dev-python/scikit-learn/scikit-learn-1.5.2.ebuild b/dev-python/scikit-learn/scikit-learn-1.5.2.ebuild
new file mode 100644
index 000000000000..5b97f0b548d5
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.5.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.19.5:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	rm -rf sklearn || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}