dev-python/tempest: Bump to 43.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index be6fa8110d61..8b269aa59ab6 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-42.0.0.tar.gz 1154522 BLAKE2B 5ff8aad2a131034507a99da82a7c279490341e4186f50aaa49498e3da697bc48ed3a61809207440d4c0a8af7ec9a487415905bb7a345df3f1e3ef5c7bca98ff4 SHA512 dcf546f08b309b9ceb08337e39b7931a3c96a591cb2578e3727b42aa74a85dd0c218cebd6708bd9592e3a39a845ef692a01df434a4f147289166c88996d11d3c
+DIST tempest-43.0.0.tar.gz 1164376 BLAKE2B 90b14dbaec468f41a08b50127299915968d53ddb0358e66ff0c4aaf1e4670e67af9905423f9ac81f9e4735ec9b03efd576595132c2f4809bc1e9a0b3d8681aea SHA512 7ed70378ddc2ee70c68c707364061ba6370cfe9bc85db4602512b6f2c163003fb9aea796da04758f0a6d2d2f666af2ace4715303370a5615fefb5886d32ddae5
diff --git a/dev-python/tempest/tempest-43.0.0.ebuild b/dev-python/tempest/tempest-43.0.0.ebuild
new file mode 100644
index 000000000000..fe2994cf869a
--- /dev/null
+++ b/dev-python/tempest/tempest-43.0.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/python-subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/testscenarios-0.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	stestr --test-path ./tempest/tests run --concurrency="$(makeopts_jobs)" ||
+		die "Tests failed for ${EPYTHON}"
+}