dev-python/sphinx: Bump to 9.0.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 145 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index b9f01a1c9211..a4885b2f52a7 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
 DIST sphinx-8.2.3.gh.tar.gz 8378376 BLAKE2B ddfa406140bebcaa09299a56fedf1170db6504a9ce3807e20c555f5e088d81acbfd19f2621a824b91199713b301380fd2056cf2282ea81f4a0858dd714eb7e45 SHA512 23066d9e98f3e36ee34ac3bc5af45792762f858e1e670145b7d1db7e98fa9e9654d87a27b9316dd72704aeea75b53f73d07d22f723c915d23a95f59bbd4f6365
 DIST sphinx-9.0.3.gh.tar.gz 8843780 BLAKE2B 4d3bb39c612f099cd93d99a7f808012a511aca7f885124de2a29aca9ff40e139cbbf340a0895a40c6e7747113839d9b69785ba501b26219b92b61f3c4a5225f9 SHA512 49014e02017d1d70a84c0877d24c13732ee936d456e01b72e53dcaa7009cdf18c9dd5d0c23d25adb718439999d2d82cbcd29ba7e97289c394f3a1cdb456fe8af
+DIST sphinx-9.0.4.gh.tar.gz 8843746 BLAKE2B 4cae21fa2b980f529f58444c4cf793ec455f5a0ea43944fa44e9e99a3d03de48f88f170e6c7382dea99cd0bb895729ee0b43cafe2aef1e84a190ea244e4c08da SHA512 8652e6a65060a81609275afa6301bb0eaccda939e2988f86d548796a215a86c923c9240422497abe77652a436479930e81dfdf43fba9722b63a50542d3ac9522
diff --git a/dev-python/sphinx/sphinx-9.0.4.ebuild b/dev-python/sphinx/sphinx-9.0.4.ebuild
new file mode 100644
index 000000000000..2342877e9dab
--- /dev/null
+++ b/dev-python/sphinx/sphinx-9.0.4.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc latex"
+
+RDEPEND="
+	>=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+	>=dev-python/babel-2.13[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.23[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-3.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+	>=dev-python/roman-numerals-py-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.2[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-applehelp-1.0.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-devhelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-jsmath-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-qthelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+"
+BDEPEND="
+	>=dev-python/flit-core-3.11
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+)
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+# EPYTEST_XDIST breaks stuff
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# roman-numerals-py has been renamed (no -py), but the package can't be pkgmoved "yet".
+	# For rc1, simply fix pip check by using the old name.
+	sed -i -e 's:roman-numerals:roman-numerals-py:' pyproject.toml || die
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3.11)
+			EPYTEST_DESELECT+=(
+				# TODO
+				tests/test_util/test_util_inspect.py::test_is_classmethod_descriptor
+				tests/test_util/test_util_inspect.py::test_is_builtin_classmethod_like
+				# minor repr() differences
+				tests/test_util/test_util_typing.py::test_restify
+				tests/test_util/test_util_typing.py::test_stringify_annotation
+				tests/test_util/test_util_typing.py::test_stringify_type_union_operator
+				# from pypy3 era
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_autodoc_exception
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_autodoc_ignore_module_all
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_autodoc_inherited_members_None
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_autodoc_subclass_of_builtin_class
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_automethod_for_builtin
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_cython
+				tests/test_ext_autodoc/test_ext_autodoc.py::test_partialfunction
+				tests/test_ext_autodoc/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+				tests/test_ext_autodoc/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+				tests/test_ext_autodoc/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+				tests/test_ext_autodoc/test_ext_autodoc_autofunction.py::test_builtin_function
+				tests/test_ext_autodoc/test_ext_autodoc_autofunction.py::test_methoddescriptor
+				tests/test_ext_autodoc/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+				tests/test_ext_autodoc/test_ext_autodoc_preserve_defaults.py::test_preserve_defaults_special_constructs
+				tests/test_ext_autodoc/test_ext_autodoc_signatures.py::test_format_class_signatures_text_signature
+				tests/test_ext_autodoc/test_ext_autodoc_signatures.py::test_format_class_signatures_no_text_signature
+				tests/test_ext_autodoc/test_ext_autodoc_signatures.py::test_format_method_signatures_error_handling
+				tests/test_ext_autosummary/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+				tests/test_ext_autosummary/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+				tests/test_util/test_util_inspect.py::test_isattributedescriptor
+				tests/test_util/test_util_inspect.py::test_signature
+				tests/test_util/test_util_typing.py::test_is_invalid_builtin_class
+			)
+			;;
+	esac
+
+	epytest
+}