dev-python/pyFFTW: Bump to 0.13.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 73 insertions, 14 deletions

diff --git a/dev-python/pyFFTW/Manifest b/dev-python/pyFFTW/Manifest
index f4fedb44f500..302bcd643357 100644
--- a/dev-python/pyFFTW/Manifest
+++ b/dev-python/pyFFTW/Manifest
@@ -1 +1,2 @@
 DIST pyFFTW-0.13.0.tar.gz 158660 BLAKE2B c54096f0814625d49832094a6d823c6d258801a0831b07846993da97a713238a5df5b59beddc38b7e940685403178b2f3100f5713334fc9861757420bc87303a SHA512 1d4c69cc19dd00f2433037f25ea90335544403b542c0c5ca00cb055e0fde076ec9e00990f02da2385466be171ed8c910a5ce06a7cfa5efbc6544b2383bbce599
+DIST pyFFTW-0.13.1.gh.tar.gz 159322 BLAKE2B f64ad74ac51c9e8c7a8137a212b43fe173a072006e3ec46e962c2bd48a3626d3c856acfc722977dc50a78afe0848ca9b25bd89b9b67168ddb285996cb18dd3ea SHA512 645d01ba94d652f9df4c5f8352f483de049df5fd846989024698365045b7b72293d9c84bd39ca2039e32db07796bbcb97eeafc8442ef4ab1de041539ed41bf9e
diff --git a/dev-python/pyFFTW/pyFFTW-0.13.1.ebuild b/dev-python/pyFFTW/pyFFTW-0.13.1.ebuild
new file mode 100644
index 000000000000..aea45023f2cf
--- /dev/null
+++ b/dev-python/pyFFTW/pyFFTW-0.13.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A pythonic python wrapper around FFTW"
+HOMEPAGE="
+	https://github.com/pyFFTW/pyFFTW/
+	https://pypi.org/project/pyFFTW/
+"
+SRC_URI="
+	https://github.com/pyFFTW/pyFFTW/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	>=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+	>=sci-libs/fftw-3.3:3.0=[threads]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-python/cython-0.29.18[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/dask-1.0[${PYTHON_USEDEP}]
+		>=dev-python/scipy-1.8.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_configure() {
+	# otherwise it'll start with -L/usr/lib, sigh
+	export PYFFTW_INCLUDE_DIR="${EPREFIX}/usr/include"
+	export PYFFTW_LIB_DIR="${EPREFIX}/usr/$(get_libdir)"
+}
+
+python_test() {
+	cp -r -l -n tests/ "${BUILD_DIR}/lib" || die
+	cd "${BUILD_DIR}/lib" || die
+	eunittest
+	rm -r tests/ || die
+}
diff --git a/dev-python/pyFFTW/pyFFTW-9999.ebuild b/dev-python/pyFFTW/pyFFTW-9999.ebuild
index db7b32f540a5..2561ff31ec5b 100644
--- a/dev-python/pyFFTW/pyFFTW-9999.ebuild
+++ b/dev-python/pyFFTW/pyFFTW-9999.ebuild
@@ -1,39 +1,45 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{8..10} )
-inherit distutils-r1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 git-r3
 
 DESCRIPTION="A pythonic python wrapper around FFTW"
-HOMEPAGE="https://github.com/pyFFTW/pyFFTW"
+HOMEPAGE="
+	https://github.com/pyFFTW/pyFFTW/
+	https://pypi.org/project/pyFFTW/
+"
+EGIT_REPO_URI="https://github.com/pyFFTW/pyFFTW.git"
 
 LICENSE="BSD"
 SLOT="0"
-if [[ "${PV}" = "9999" ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/pyFFTW/pyFFTW.git"
-else
-	KEYWORDS="~amd64 ~x86"
-	SRC_URI="https://github.com/pyFFTW/pyFFTW/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-fi
 
 DEPEND="
-	>=dev-python/numpy-1.16[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.20[${PYTHON_USEDEP}]
 	>=sci-libs/fftw-3.3:3.0=[threads]
 "
-RDEPEND="${DEPEND}"
+RDEPEND="
+	${DEPEND}
+"
 BDEPEND="
 	>=dev-python/cython-0.29.18[${PYTHON_USEDEP}]
 	test? (
 		>=dev-python/dask-1.0[${PYTHON_USEDEP}]
-		>=dev-python/scipy-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/scipy-1.8.0[${PYTHON_USEDEP}]
 	)
 "
 
 distutils_enable_tests unittest
 
+src_configure() {
+	# otherwise it'll start with -L/usr/lib, sigh
+	export PYFFTW_INCLUDE_DIR="${EPREFIX}/usr/include"
+	export PYFFTW_LIB_DIR="${EPREFIX}/usr/$(get_libdir)"
+}
+
 python_test() {
 	cp -r -l -n tests/ "${BUILD_DIR}/lib" || die
 	cd "${BUILD_DIR}/lib" || die