dev-python/pylint: Bump to 4.0.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 91937d537fc66..f062286c33a4c 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1 +1,3 @@
 DIST pylint-4.0.4.gh.tar.gz 1509805 BLAKE2B ded555fa6a1c5109fce113613c2ac73377a57418a70034121199ef0b77207b3447ccfdf66324f774bf02d6153efec3c39b1cc6e9a515c44e96fc05327f4c52aa SHA512 1ef16eda98c95edd4932d5a09f9e7fcc4cfcf5989838367b43d54a9b58b1edd96eaec2d13a87a5c7ca75e48b5f408d12742b19660a55954b7067ec66783f1048
+DIST pylint-4.0.5.tar.gz 1572474 BLAKE2B fdc5b999151fdb88bef549bd2e2c93561242b1ac4cf137a95fb14f6f96cfe4dec113ce743366ea586ca4556cc9c403f1bae5136f6613184c012d620e60b6ec0f SHA512 96959f57f7730e8b6fd281afa5429a0a1ebe4815db9ffb175498e18b3132f7e52e04dbc9da3818d460a565567d27072f06cf79b21ea4be82ad7618ae6ff1be40
+DIST pylint-4.0.5.tar.gz.provenance 9456 BLAKE2B b2ba66073acdd3c9c9fadf21b0743c67c186e301e1ced8c4ada6e0f8a9d5b90854cabdc37e3000ea2417db360d20113e944bf59b9523601d42f1d786a29aab51 SHA512 24e5ab2e6f8f590627106b3e999fab48d9c46ec21fbaac92c553a53b469f9ef26082112e3059aaa43579f068e26166fc6878a78a784035d8bfe3b09520435b2f
diff --git a/dev-python/pylint/pylint-4.0.5.ebuild b/dev-python/pylint/pylint-4.0.5.ebuild
new file mode 100644
index 0000000000000..183beb0b06060
--- /dev/null
+++ b/dev-python/pylint/pylint-4.0.5.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/pylint-dev/pylint
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+	https://pypi.org/project/pylint/
+	https://github.com/pylint-dev/pylint/
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	<dev-python/astroid-4.1[${PYTHON_USEDEP}]
+	>=dev-python/astroid-4.0.2[${PYTHON_USEDEP}]
+	>=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/isort-5.14[${PYTHON_USEDEP}]
+	<dev-python/isort-9[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/gitpython-3[${PYTHON_USEDEP}]
+		' 'python*' )
+		>=dev-python/pytest-8.3[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-timeout )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		'tests/test_functional.py::test_functional[dataclass_with_field]'
+		'tests/test_functional.py::test_functional[no_name_in_module]'
+		'tests/test_functional.py::test_functional[shadowed_import]'
+		'tests/test_functional.py::test_functional[use_yield_from]'
+	)
+	local EPYTEST_IGNORE=(
+		# No need to run the benchmarks
+		tests/benchmark/test_baseline_benchmarks.py
+		# Internal stuff, missing data in sdist
+		tests/testutils/_primer/test_primer.py
+	)
+
+	if ! has_version "dev-python/gitpython[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/profile/test_profile_against_externals.py
+			tests/testutils/_primer/test_package_to_lint.py
+			tests/testutils/_primer/test_primer.py
+		)
+	fi
+
+	epytest
+}
+
+python_install_all() {
+	if use examples ; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}