dev-python/scikit-learn: Bump to 1.7.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index 5b8fd7591315..b51f7c0f95bb 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1 +1,2 @@
 DIST scikit-learn-1.7.0.gh.tar.gz 7155945 BLAKE2B bd95523f81d64c1eca8bb162372344a91331007a0a0c9764d84fd6e92ce5ae4f72f9595598e8ea806b7bcfcff1f97e020bb6976a738fcca8c0f22ae348355207 SHA512 9093af3df99bdb9dc3961e4ba576ec53a2fd27c9a6dbe49b24a9cc9de9ae33536dff7c68c4430ff0c29bd4e0e2ee05f937c94b048a2443aa92c7258a82011fca
+DIST scikit-learn-1.7.1.gh.tar.gz 7171470 BLAKE2B 3f5e849ff70d87db4706340f9b05354dea9797614df0435479a9fba1c8dde2862ea5b2d9de3dd8047156b54879e89fecbaf17fb12fb7e21d82a1e56bc9c47d55 SHA512 dc1942947bae261cd314aed333cf4b67e54de9433069c8fd4af89c3d473761ce37e7939ec402952456147766be721e600328aef3fcfa9806eff9e17701a2828b
diff --git a/dev-python/scikit-learn/scikit-learn-1.7.1.ebuild b/dev-python/scikit-learn/scikit-learn-1.7.1.ebuild
new file mode 100644
index 000000000000..0e17b12cc9c0
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.7.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV/_}.tar.gz
+		-> ${P/_}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.22.0:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	case ${ARCH} in
+		ppc64)
+			EPYTEST_DESELECT+=(
+				# TODO
+				ensemble/_weight_boosting.py::sklearn.ensemble._weight_boosting.AdaBoostRegressor
+			)
+	esac
+
+	rm -rf sklearn || die
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}