dev-python/ipykernel: Bump to 7.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 8550128378d9..bfae845dff85 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,3 +1,4 @@
 DIST ipykernel-6.30.1.tar.gz 166260 BLAKE2B 77af93248f25479aae9082ef6e73dcab23b0724e53029a8b52fa99f217ea6482e1a2ed7e21a7b95ea88065acc8530e159d19b2a5c3b2fe5ef72c513059f2a524 SHA512 45bd9e79f3a74d3694034de3f367b913171b027e913e9f7cd1fdcfb17db09927e0ee300253ad9061d668559c5bf353bddbaf01ea52bcf5a9624a0a4a21050759
 DIST ipykernel-6.31.0.tar.gz 167493 BLAKE2B 0cb5f208b5cc1fc2d9da971cdd63158865036006ffbe697a375bf81e7242a99f168e9b6c8cdb1a2e3da46a973a1ed8b9ab2c1455de15a33f010b78db2fd939af SHA512 3ace064d1c78eb55d6f5f201349eb4a5b64eee387ea9adf4b7ad69875e15839eaecfd1940379dee367fbbba01426454ab70dc1526a7dd7cfdb250b31340d5872
 DIST ipykernel-7.1.0.tar.gz 174579 BLAKE2B 61827326e033648643da186f11b9376265eb486f7eeb05140817e2377ea605079a172577c87c3b8605ba547fb9f41e72749052aa260c2e4c1f76d9a3be792e4b SHA512 5b7c7960c46a761af0d0407d66832bd78ef304c6ee7b0e2aaffd1a99fb0a32cee21480d5f436759328688d4ff2a1f0c24df0716da13260d22734b5acc41dbcb7
+DIST ipykernel-7.2.0.tar.gz 176046 BLAKE2B 8cdba3db6ced2a5a9226077e72bcc4b2825869043d4b918bb8b8e989b6d6fa5cb0b6911aba942823177bedf7aaaf5385c84df56d18214ca38c17730da87de974 SHA512 b49cf006f4cd552f173b3341672e0a4dd3f68906f4c85ed924d128b85564bfb98a76dc23d68eb9fcad5f64f2aba9bca9e15e74a7a383667fab1b998bc019ae86
diff --git a/dev-python/ipykernel/ipykernel-7.2.0.ebuild b/dev-python/ipykernel/ipykernel-7.2.0.ebuild
new file mode 100644
index 000000000000..59b9b790c7e1
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-7.2.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8.8.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-5.1[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	>=dev-python/nest-asyncio-1.4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.7[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-25[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.4.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+# pytest-8 runs a small subset of tests, we allow newer for 3.13
+# since a few tests are better than skipping entirely
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{asyncio,rerunfailures,timeout} )
+distutils_enable_tests pytest
+
+src_prepare() {
+	# debugpy is actually optional
+	sed -i -e '/debugpy/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# hangs?
+		tests/test_eventloop.py::test_tk_loop
+		# flaky
+		tests/test_eventloop.py::test_qt_enable_gui
+		# fails without pytest-cov; apparently "time-sensitive" too
+		tests/test_subshells.py::test_run_concurrently_sequence
+	)
+
+	case ${EPYTHON} in
+		python3.14)
+			EPYTEST_DESELECT+=(
+				tests/test_kernel.py::test_subprocess_{error,print}
+			)
+			;;
+	esac
+
+	epytest
+}