dev-python/parso: Enable py3.14

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/parso/parso-0.8.4-r1.ebuild b/dev-python/parso/parso-0.8.4-r1.ebuild
new file mode 100644
index 000000000000..146229fc4ad5
--- /dev/null
+++ b/dev-python/parso/parso-0.8.4-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="A python parser that supports error recovery and round-trip parsing"
+HOMEPAGE="
+	https://github.com/davidhalter/parso/
+	https://pypi.org/project/parso/
+"
+SRC_URI="
+	https://github.com/davidhalter/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# py3.10 changed exception messages
+	test/test_python_errors.py::test_python_exception_matches
+	# With python3.11 this additional file is run by pytest,
+	# but it is not actually a test and thus fails
+	parso/python/token.py::parso.python.token.PythonTokenTypes
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# this ain't perfect but that's what upstream has so far
+	# https://github.com/davidhalter/parso/commit/f670e6e7dc01e07576ec5c84cbf9fbce1a02c3eb
+	cp parso/python/grammar{313,314}.txt || die
+}