dev-python/vcrpy: Reenable all tests

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 69 insertions, 0 deletions

diff --git a/dev-python/vcrpy/vcrpy-6.0.1-r1.ebuild b/dev-python/vcrpy/vcrpy-6.0.1-r1.ebuild
new file mode 100644
index 000000000000..b82fe8880935
--- /dev/null
+++ b/dev-python/vcrpy/vcrpy-6.0.1-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Automatically mock your HTTP interactions to simplify and speed up testing"
+HOMEPAGE="
+	https://github.com/kevin1024/vcrpy/
+	https://pypi.org/project/vcrpy/
+"
+SRC_URI="
+	https://github.com/kevin1024/vcrpy/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/httplib2-0.9.1[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.16.2[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pytest-httpbin-2.0.0-r1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/kevin1024/vcrpy/pull/823
+	"${FILESDIR}/${P}-httpbin-compat.patch"
+)
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# these tests are failing with recent dev-python/werkzeug; losely related:
+		# https://github.com/kevin1024/vcrpy/issues/645
+		tests/integration/test_record_mode.py::test_new_episodes_record_mode_two_times
+		tests/integration/test_urllib2.py::test_random_body
+		tests/integration/test_urllib2.py::test_multiple_requests
+		# Internet
+		"tests/integration/test_urllib3.py::test_post[https]"
+	)
+
+	local EPYTEST_IGNORE=(
+		# requires boto3
+		tests/integration/test_boto3.py
+		# Internet
+		tests/integration/test_tornado.py
+		tests/integration/test_aiohttp.py
+	)
+
+	local -x REQUESTS_CA_BUNDLE=$("${EPYTHON}" -m pytest_httpbin.certs)
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m 'not online' -p httpbin -p rerunfailures --reruns=5
+}