dev-python/qiskit: Bump to 2.3.0_rc1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 122 insertions, 0 deletions

diff --git a/dev-python/qiskit/Manifest b/dev-python/qiskit/Manifest
index 2d698b65557c..430e6710f54d 100644
--- a/dev-python/qiskit/Manifest
+++ b/dev-python/qiskit/Manifest
@@ -1,2 +1,4 @@
 DIST qiskit-2.2.0-crates.tar.xz 16407880 BLAKE2B 7445aba25d26ed3826e70549d16551588acce28847545b20b6c64f96b39f0cca9ca17ada7c7ed2aadd513e22355ab55e29e41218efe7201779bf39e9e5440e7c SHA512 f156de95eea02b7d5fc3838ba0369cfbb51f92ee13b59035c6f79c29528f3d2888ebc3f6917324587b33b656962b16513a3f17b47e8248cd9f1b88ce497d51b6
 DIST qiskit-2.2.3.gh.tar.gz 7327304 BLAKE2B 3b2cdf0fc29d260184328d841be93d046a480a6d5ae4a0405efd44a5fd50198cbf724de8c0da56b75cb87315a8798a28bc8dd408589344094eb8d59e22b3f0ea SHA512 56704b509628145735979b4acaab6f37bb7caf51de325e21281c0abcfda62f5e0846d5bb29f2bc38c9cbfb4f9a4c07c6da2cde51ec15b717821414e132286dea
+DIST qiskit-2.3.0rc1-crates.tar.xz 25052004 BLAKE2B 49555e09c47e1754efcef5768a92b240a893a374ea9b37d4aa0bb5677cb7e02ad9b18e39d018da6062eae132f73db597225ff274a2a5b6fcd6be71ac1bc3cfa4 SHA512 66ef106005ff44ba79c25a9e902a6f5a3284d247de2b550a338e23f72df7331b7bde2895ee71a514628256f0e54a9ac11c4e4f0fc91e12c2c89567d717c7efb6
+DIST qiskit-2.3.0rc1.gh.tar.gz 7489390 BLAKE2B b1e69d1972e3319e3ad66eb4aa82d7e678653353d1cda37dfded65bbd65e495a7441936f3d6635cd4e44579e70354becc5f3ffa3571813052dfc29bb04c9a576 SHA512 a87d0aa83fceaca395f76dc6bb5a76ad2967f4643e5751df36bdf339d8540226314c2279c610e5c017166c4cad606b68061b5f8ce4a4a22d0f88005488d563e0
diff --git a/dev-python/qiskit/qiskit-2.3.0_rc1.ebuild b/dev-python/qiskit/qiskit-2.3.0_rc1.ebuild
new file mode 100644
index 000000000000..162bb803c616
--- /dev/null
+++ b/dev-python/qiskit/qiskit-2.3.0_rc1.ebuild
@@ -0,0 +1,120 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+CRATES="
+"
+RUST_MIN_VER="1.84.0"
+
+inherit cargo distutils-r1
+
+MY_P=${P/_}
+CRATE_PV=${PV/_}
+DESCRIPTION="An open-source SDK for working with quantum computers"
+HOMEPAGE="
+	https://github.com/Qiskit/qiskit/
+	https://pypi.org/project/qiskit/
+"
+SRC_URI="
+	https://github.com/Qiskit/qiskit/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+	https://github.com/gentoo-crate-dist/qiskit/releases/download/${CRATE_PV/_}/${PN}-${CRATE_PV}-crates.tar.xz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 MIT MPL-2.0
+	Unicode-3.0 ZLIB
+"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~amd64"
+fi
+IUSE="+visualization"
+
+RDEPEND="
+	>=dev-python/dill-0.3[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/python-constraint-1.4[${PYTHON_USEDEP}]
+	>=dev-python/rustworkx-0.15.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.5[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-3.0.0[${PYTHON_USEDEP}]
+	visualization? (
+		>=dev-python/matplotlib-3.3[${PYTHON_USEDEP}]
+		dev-python/pydot[${PYTHON_USEDEP}]
+		>=dev-python/pillow-4.2.1[${PYTHON_USEDEP}]
+		>=dev-python/pylatexenc-1.4[${PYTHON_USEDEP}]
+		>=dev-python/seaborn-0.9.0[${PYTHON_USEDEP}]
+		>=dev-python/symengine-0.11.0[${PYTHON_USEDEP}]
+		>=dev-python/sympy-1.3[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/cython-0.27.1[${PYTHON_USEDEP}]
+	test? (
+		app-text/poppler[png]
+		>=dev-python/ddt-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/networkx-2.2[${PYTHON_USEDEP}]
+		>=dev-python/qiskit-aer-0.14[${PYTHON_USEDEP}]
+		>=dev-python/scikit-learn-0.20.0[${PYTHON_USEDEP}]
+	)
+"
+
+# Files built without CFLAGS/LDFLAGS, acceptable for rust
+QA_FLAGS_IGNORED="
+	usr/lib.*/py.*/site-packages/qiskit/_accelerate.*.so
+	usr/lib.*/py.*/site-packages/qiskit/_qasm2.*.so
+"
+
+EPYTEST_PLUGINS=( hypothesis )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip forcing -Werror from tests that also leaks to other packages
+	sed -i -e '/filterwarnings.*error/d' test/utils/base.py || die
+}
+
+python_test() {
+	# We run tests in parallel, so avoid having n^2 threads in lapack
+	# tests.
+	local -x BLIS_NUM_THREADS=1
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local -x OPENBLAS_NUM_THREADS=1
+
+	local EPYTEST_DESELECT=(
+		# TODO
+		test/python/circuit/test_equivalence.py::TestEquivalenceLibraryVisualization::test_equivalence_draw
+		test/python/transpiler/test_unitary_synthesis_plugin.py::TestUnitarySynthesisPlugin
+		test/python/visualization/test_dag_drawer.py::TestDagDrawer::test_dag_drawer_no_register
+		# tiny image differences, sigh
+		test/python/visualization/test_gate_map.py::TestGateMap::test_plot_error_map_over_100_qubit
+		# TODO: failures from dill
+		test/python/circuit/test_parameters.py::TestParameters::test_transpiling_multiple_parameterized_circuits
+		test/python/compiler/test_transpiler.py::TestTranspile::test_delay_converts_expr_to_dt
+		test/python/compiler/test_transpiler.py::TestTranspile::test_transpile_two
+		test/python/transpiler/test_naming_transpiled_circuits.py::TestNamingTranspiledCircuits::test_multiple_circuits_name_list
+	)
+
+	local EPYTEST_IGNORE=(
+		# Breaks xdist
+		test/python/qasm2/test_parse_errors.py
+		test/python/transpiler/test_preset_passmanagers.py
+	)
+
+	rm -rf qiskit || die
+	# Run the Python test suite rather than everything under test/ which
+	# includes the 'randomized' suite. Upstream run that in a separate CI job.
+	epytest test/python
+}