dev-ruby/dnsruby: add 1.72.4

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/dnsruby/dnsruby-1.72.4.ebuild b/dev-ruby/dnsruby/dnsruby-1.72.4.ebuild
new file mode 100644
index 000000000000..5bd8ef5c7eb2
--- /dev/null
+++ b/dev-ruby/dnsruby/dnsruby-1.72.4.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_TASK_TEST=""
+RUBY_FAKEGEM_DOCDIR="html"
+RUBY_FAKEGEM_EXTRADOC="DNSSEC EXAMPLES README.md"
+inherit ruby-fakegem
+
+DESCRIPTION="A pure Ruby DNS client library"
+HOMEPAGE="https://github.com/alexdalitz/dnsruby"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+
+ruby_add_rdepend "
+	dev-ruby/base64:0.2
+	>=dev-ruby/logger-1.6.5:0 =dev-ruby/logger-1.6*
+	>=dev-ruby/simpleidn-0.2.1:0 =dev-ruby/simpleidn-0.2*:0"
+
+ruby_add_bdepend "test? ( >=dev-ruby/minitest-5.4:5 )"
+
+all_ruby_prepare() {
+	sed -i -e "/[Cc]overall/d" Rakefile || die
+	sed -i -e '/display/d' \
+		-e '/Display/,/^}/d' test/spec_helper.rb || die
+}
+
+each_ruby_test() {
+	# only run offline tests
+	# ${RUBY} -I .:lib test/ts_dnsruby.rb || die "test failed"
+	${RUBY} -I .:lib test/ts_offline.rb || die "test failed"
+}