dev-ruby/rubyzip: add 1.2.2

Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ruby/rubyzip/rubyzip-1.2.2.ebuild b/dev-ruby/rubyzip/rubyzip-1.2.2.ebuild
new file mode 100644
index 000000000000..7a792840be6d
--- /dev/null
+++ b/dev-ruby/rubyzip/rubyzip-1.2.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md TODO"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A ruby library for reading and writing zip files"
+HOMEPAGE="https://github.com/rubyzip/rubyzip"
+# Tests are not included in the gem.
+SRC_URI="https://github.com/rubyzip/rubyzip/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="Ruby"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=""
+DEPEND="${DEPEND} test? ( app-arch/zip )"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest:5 )"
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc samples/*
+}
+
+all_ruby_prepare() {
+	# Avoid dependencies on simplecov and coveralls
+	sed -i -e '/simplecov/ s:^:#:' test/test_helper.rb || die
+
+	# Avoid dependency on bundler
+	sed -i -e '/bundler/ s:^:#:' Rakefile || die
+
+	# Fix hardcoded path to /tmp
+	sed -i -e 's:/tmp/:'${T}'/:g' test/entry_test.rb || die
+
+	# Add missing requires
+	sed -i -e '1irequire "forwardable"; require "pathname"' test/input_stream_test.rb || die
+}