dev-scheme/c-wrapper: fix finalizer of ffi_closure

Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-scheme/c-wrapper/c-wrapper-0.6.1-r1.ebuild b/dev-scheme/c-wrapper/c-wrapper-0.6.1-r1.ebuild
new file mode 100644
index 000000000000..709c8c2eb641
--- /dev/null
+++ b/dev-scheme/c-wrapper/c-wrapper-0.6.1-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools
+
+DESCRIPTION="Foreign function interface for C and Objective-C libraries"
+HOMEPAGE="http://www.koguro.net/prog/c-wrapper/"
+SRC_URI="http://www.koguro.net/prog/${PN}/${P}.tgz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 x86"
+IUSE="examples"
+
+RDEPEND="dev-scheme/gauche
+	virtual/libffi"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-closure.patch
+	"${FILESDIR}"/${PN}-gentoo.patch
+)
+HTML_DOCS=( doc/${PN}-ref{e,j}.html )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_test() {
+	emake -j1 -s check
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}