gnome-extra/evolution-ews: add 3.58.2

Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://github.com/gentoo/gentoo/pull/44343
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index 54142c1fbf83..31c3b18e0921 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -2,3 +2,4 @@ DIST evolution-ews-3.52.4.tar.xz 724244 BLAKE2B 35b78fa600e06c18cecee8c43941e77b
 DIST evolution-ews-3.54.3.0.tar.xz 737492 BLAKE2B bf78efdc60953c7723eaf952456b97b42d9189437d1d6fe535c3d73724df5d89856f144474890359154058080616cf610cb3b58f170a6c4b247c6fb0907af122 SHA512 f914daab6d5765c18c8f58583a97ce41aacf8a7ebe43c250d3ce764062846beae03e4bdc1f11ea7f0182a74ac7b976f74c88043b8a8a323af8866aa6e0bf0515
 DIST evolution-ews-3.56.1.tar.xz 756468 BLAKE2B 0252978c6d8e36a7fda7ff5583d12c3c604b91c29e1439d86e1de62826a4df08fef83dccc25eae0bcb9ea9ed93d107a3e99f79ec1a37a5f43cdc887306d366dc SHA512 fe3521214f7ea5d95706fa2c159bb5cf9bb53611e643a766f6a88f66f274d5c25bda982783bfa757d34c3a9f044cdd89a7c7f4118413fcc0fedb1a34b3907737
 DIST evolution-ews-3.56.2.tar.xz 756844 BLAKE2B 552b8ffac41f4effdab19af73649386ffbd6dab2ff6d7013cf20ae4375bb6f070b16de2889866fca666214ff18490ca20daeccc1f2f45d9d05c2e000da9a808a SHA512 5213a6071ff5f1077eae19b9ab163f72f945b9fc7ab325733c3f6fa6be9bba16dfc1bd416d4d9786d4a16e2cf3e18f4eafb1f31a75c5487884f1c5ce5644866b
+DIST evolution-ews-3.58.2.tar.xz 768164 BLAKE2B 3b91f141aa0e196cba9a1a5a08928f9355353e35f0b37f96abb4d30da20f278a1ff2435292f8ee63bc46c5991681be82ba742d607748265341bb4fd695195468 SHA512 92b265b7278f80ac0c77d0a03800b7a5149ce2f52b70256c4039f386649b91c341ab9a0c29461e6540d594e19b918196457abe8a83684a96d976d8fa4dacd37a
diff --git a/gnome-extra/evolution-ews/evolution-ews-3.58.2.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.58.2.ebuild
new file mode 100644
index 000000000000..de2ed447ae57
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.58.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/evolution/-/wikis/home https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[glib]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-3.54.3:0=
+	>=mail-client/evolution-3.54.3:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" "gnome-extra/evolution-data-server[oauth-gtk3]"
+}