llvm-core/llvm-common: Add 21.1.0_rc2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/llvm-core/llvm-common/llvm-common-21.1.0_rc2.ebuild b/llvm-core/llvm-common/llvm-common-21.1.0_rc2.ebuild
new file mode 100644
index 000000000000..2e0edb2d0ea7
--- /dev/null
+++ b/llvm-core/llvm-common/llvm-common-21.1.0_rc2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common llvm.org
+
+DESCRIPTION="Common files shared between multiple slots of LLVM"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+IUSE="emacs"
+
+RDEPEND="
+	!llvm-core/llvm:0
+"
+BDEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+
+LLVM_COMPONENTS=( llvm/utils )
+llvm.org_set_globals
+
+SITEFILE="50llvm-gentoo.el"
+BYTECOMPFLAGS="-L emacs"
+
+src_compile() {
+	default
+
+	use emacs && elisp-compile emacs/*.el
+}
+
+src_install() {
+	insinto /usr/share/vim/vimfiles
+	doins -r vim/*/
+	# some users may find it useful
+	newdoc vim/README README.vim
+	dodoc vim/vimrc
+
+	if use emacs ; then
+		elisp-install llvm emacs/*.{el,elc}
+		elisp-make-site-file "${SITEFILE}" llvm
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}