1 files changed, 54 insertions, 0 deletions
diff --git a/dev-java/commons-net/commons-net-3.11.1.ebuild b/dev-java/commons-net/commons-net-3.11.1.ebuild
new file mode 100644
index 000000000000..2563be67f5d0
--- /dev/null
+++ b/dev-java/commons-net/commons-net-3.11.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# No tests, #839681
+JAVA_PKG_IUSE="doc examples source"
+MAVEN_ID="commons-net:commons-net:${PV}"
+
+inherit java-pkg-2 java-pkg-simple verify-sig
+
+DESCRIPTION="Client-oriented Java library to implement many Internet protocols"
+HOMEPAGE="https://commons.apache.org/proper/commons-net/"
+SRC_URI="mirror://apache/commons/net/source/${P}-src.tar.gz
+	verify-sig? ( https://downloads.apache.org/commons/net/source/${P}-src.tar.gz.asc )"
+S="${WORKDIR}/${P}-src"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/commons.apache.org.asc"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-apache-commons )"
+DEPEND=">=virtual/jdk-11:*"	# module-info
+RDEPEND=">=virtual/jre-1.8:*"
+
+DOCS=(
+	CONTRIBUTING.md
+	NOTICE.txt
+	README.md
+	RELEASE-NOTES.txt
+)
+
+JAVA_RESOURCE_DIRS="src/main/resources"
+JAVA_SRC_DIR="src/main/java"
+
+src_prepare() {
+	java-pkg-2_src_prepare
+	rm -r src/main/{java,resources}/org/apache/commons/net/examples || die
+}
+
+src_compile() {
+	JAVA_JAR_FILENAME="org.apache.${PN}.jar"
+	java-pkg-simple_src_compile	# creates a legacy jar file without module-info
+
+	jdeps --generate-module-info \
+		src/main/java \
+		--multi-release 9 \
+		"${JAVA_JAR_FILENAME}" || die
+
+	JAVA_JAR_FILENAME="${PN}.jar"
+	java-pkg-simple_src_compile	# creates the final jar file including module-info
+
+}