1 files changed, 0 insertions, 70 deletions
diff --git a/dev-lua/luaposix/luaposix-35.0-r100.ebuild b/dev-lua/luaposix/luaposix-35.0-r100.ebuild
deleted file mode 100644
index 7881ac5e4801..000000000000
--- a/dev-lua/luaposix/luaposix-35.0-r100.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-LUA_COMPAT=( lua5-{1..4} luajit )
-
-inherit lua toolchain-funcs
-
-DESCRIPTION="Bindings for POSIX APIs"
-HOMEPAGE="https://luaposix.github.io/luaposix/ https://github.com/luaposix/luaposix"
-SRC_URI="https://github.com/luaposix/luaposix/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-SLOT="0"
-LICENSE="MIT"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-# Requires specl, which is not in the tree yet
-RESTRICT="test"
-
-DEPEND="${LUA_DEPS}"
-RDEPEND="${DEPEND}
-	lua_targets_lua5-1? ( dev-lua/lua-bit32[lua_targets_lua5-1(-)] )
-	lua_targets_luajit? ( dev-lua/lua-bit32[lua_targets_luajit(-)] )"
-BDEPEND="virtual/pkgconfig"
-
-src_prepare() {
-	default
-
-	# Temporary fix for respect LDFLAGS (#739050)
-	# Fixed in luke 0.2.1
-	sed -i -e "s:c_module,libdirs:c_module,'\$LDFLAGS',libdirs:g" \
-		build-aux/luke || die
-
-	lua_copy_sources
-}
-
-lua_src_compile() {
-	pushd "${BUILD_DIR}" || die
-
-	./build-aux/luke package="${PN}" version="${PV}" \
-		PREFIX="${ED}/usr" \
-		INST_LIBDIR="${ED}/$(lua_get_cmod_dir)" \
-		INST_LUADIR="${ED}/$(lua_get_lmod_dir)" \
-		CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" CC="$(tc-getCC)" || die
-
-	popd
-}
-
-src_compile() {
-	lua_foreach_impl lua_src_compile
-}
-
-lua_src_install() {
-	pushd "${BUILD_DIR}" || die
-
-	./build-aux/luke install \
-		PREFIX="${ED}/usr" \
-		INST_LIBDIR="${ED}/$(lua_get_cmod_dir)" \
-		INST_LUADIR="${ED}/$(lua_get_lmod_dir)" \
-		|| die
-
-	popd
-}
-
-src_install() {
-	lua_foreach_impl lua_src_install
-	dodoc -r doc NEWS.md README.md
-}