1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/PyECLib/PyECLib-1.6.1.ebuild b/dev-python/PyECLib/PyECLib-1.6.1.ebuild
new file mode 100644
index 000000000000..8fa3328630d7
--- /dev/null
+++ b/dev-python/PyECLib/PyECLib-1.6.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+MY_P=${P,,}
+DESCRIPTION="Messaging API for RPC and notifications over different messaging transports"
+HOMEPAGE="
+	https://opendev.org/openstack/pyeclib/
+	https://pypi.org/project/pyeclib/
+"
+SRC_URI="mirror://pypi/${MY_P::1}/${PN,,}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	dev-libs/liberasurecode
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# https://review.opendev.org/c/openstack/pyeclib/+/798010
+	sed -e '/library_dirs/d' -i setup.py || die
+	distutils-r1_src_prepare
+}
+
+pkg_postinst() {
+	optfeature "jerasure backend" dev-libs/jerasure
+}