2 files changed, 65 insertions, 0 deletions
diff --git a/dev-python/b2sdk/Manifest b/dev-python/b2sdk/Manifest
index 534f6e6d7a0c..6408646a030b 100644
--- a/dev-python/b2sdk/Manifest
+++ b/dev-python/b2sdk/Manifest
@@ -1 +1,2 @@
 DIST b2sdk-2.10.1.gh.tar.gz 423901 BLAKE2B 13695181133e0df9a313cc0352f10f3d7dd5b301c87f6edce1ef88292eee2fdf78a48d79a8a3690c43abeb6dac3193955371260aa126bb9b0bcd1f0a67f99f4c SHA512 c2c74bd1ae33801ef2f3a13781a423efd10843283a2b976ccbf4baac80a586be2b827f862fa1d0d8b7bdcd662c75a37b4687b162672421a040c74ca47fb272c5
+DIST b2sdk-2.10.2.gh.tar.gz 431919 BLAKE2B 5afc6b1d832b449551d1093e788c0ff518dc589c9d968555fa72ad4684d14f9f64681a6f78a55cc125aaf43416202b390eecbef246067d2bb948f730aa564e7f SHA512 633715c57bc61d1fa55bf86ab9ad838099f8670aab0b76a82c979ed79d2feac106daf8a067123733ff74c08f77d1cf35377057c18c29c0705d5f902b759a7b69
diff --git a/dev-python/b2sdk/b2sdk-2.10.2.ebuild b/dev-python/b2sdk/b2sdk-2.10.2.ebuild
new file mode 100644
index 000000000000..6aaa3e6bb025
--- /dev/null
+++ b/dev-python/b2sdk/b2sdk-2.10.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Library to access Backblaze B2 cloud storage"
+HOMEPAGE="
+	https://github.com/Backblaze/b2-sdk-python
+	https://pypi.org/project/b2sdk/
+"
+# No tests in sdist
+SRC_URI="https://github.com/Backblaze/b2-sdk-python/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/b2-sdk-python-${PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# pydantic can be used but it has a fallback
+RDEPEND="
+	>=dev-python/annotated-types-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/logfury-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.9.1[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-9.1.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/tqdm-4.5.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Requires network access and real API keys
+	test/integration/test_bucket.py
+	test/integration/test_download.py
+	test/integration/test_file_version_attributes.py
+	test/integration/test_sync.py
+	test/integration/test_upload.py
+	test/integration/test_raw_api.py
+	# ... and they fail to import w/ pytest-8.4.1 anyway because of
+	# pytest_plugins at non-top-level.
+	test/integration
+)
+
+EPYTEST_PLUGINS=( pytest-{lazy-fixtures,mock,timeout} )
+distutils_enable_tests pytest
+
+export PDM_BUILD_SCM_VERSION=${PV}
+
+python_test() {
+	if [[ ${EPYTHON} == python3.14 ]] ; then
+		local EPYTEST_DESELECT=(
+			# Error message differs w/ 3.14
+			test/unit/scan/test_folder_traversal.py::TestFolderTraversal::test_dir_without_exec_permission
+		)
+	fi
+
+	epytest
+}