4 files changed, 126 insertions, 0 deletions
diff --git a/dev-python/bokeh/Manifest b/dev-python/bokeh/Manifest
new file mode 100644
index 000000000000..8a4393da9717
--- /dev/null
+++ b/dev-python/bokeh/Manifest
@@ -0,0 +1 @@
+DIST bokeh-0.7.1.tar.gz 30039486 SHA256 167125e07df2ea1f65b1b6dfed140b7b6ed7452a1182ad4cb0be2580af537f73 SHA512 cf2ee6457cab7ca0a98c2cf19a7814e081245b30cf6f4f4670f8fc60b216bb39f14d3cdf52c92f85635cbf6419db00c0c01adb2e1a6eeaa019cdc767c642c160 WHIRLPOOL 23e66370f1cab2d3a3c40b0713e5cdb50afa7aeec1c2d1172a1d9a5598c004dd351509973ac84f24ebb30dbc5a86de455e1dfcbe00daf6a1d12c3e336122a2b8
diff --git a/dev-python/bokeh/bokeh-0.7.1.ebuild b/dev-python/bokeh/bokeh-0.7.1.ebuild
new file mode 100644
index 000000000000..06993090ae63
--- /dev/null
+++ b/dev-python/bokeh/bokeh-0.7.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1 readme.gentoo
+
+DESCRIPTION="Statistical and interactive HTML plots for Python"
+HOMEPAGE="http://bokeh.pydata.org/"
+SRC_URI="https://github.com/ContinuumIO/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+IUSE="examples test"
+
+# A doc build requires napoleon sphinx extension which will be included in sphinx release 1.3
+# Therefore refraining from adding the doc build for now
+RDEPEND="
+	>=dev-python/colorama-0.2.7[${PYTHON_USEDEP}]
+	>=dev-python/click-3.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7[${PYTHON_USEDEP}]
+	>=dev-python/markdown-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-0.18[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.11[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	>=dev-python/pystache-0.5.3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013b[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-14.3.1[${PYTHON_USEDEP}]
+	>=dev-python/redis-py-2.7.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-1.2.3[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.9.1[${PYTHON_USEDEP}]
+	>=net-libs/nodejs-0.8.28[npm]
+	>=www-client/phantomjs-1.9.8
+	>=www-servers/tornado-4.0.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/gevent-1.0[${PYTHON_USEDEP}]' python2_7)
+	$(python_gen_cond_dep '>=dev-python/gevent-websocket-0.9.2[${PYTHON_USEDEP}]' python2_7)
+	"
+# testing server: needs websocket not in portage yet
+# websocket is in pypi for the adding
+# hdf5 backend: needs array management not in portage yet
+DEPEND="
+	test? (
+		${RDEPEND}
+		>=dev-python/nose-1.3.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]' python2_7)
+		>=dev-python/colorama-0.2.7[${PYTHON_USEDEP}] )
+	"
+DOCS=( CHANGELOG QUICKSTART.md README.md )
+
+PATCHES=( "${FILESDIR}"/${P}-setup.patch )
+
+DISTUTILS_NO_PARALLEL_BUILD=1
+
+python_prepare_all() {
+	DOC_CONTENTS="websockets work only with python2_7"
+
+	sed -i -e "s/jsbuild = get_user_jsargs()/jsbuild = False/g" setup.py || die
+	cd bokehjs || die
+	npm install ||die
+	cd .. || die
+	esetup.py --build_js sdist
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	readme.gentoo_create_doc
+
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	# exclude server tests for now
+	nosetests -v \
+		-e multiuser_auth_test \
+		-e usermodel_test \
+		|| die
+}
diff --git a/dev-python/bokeh/files/bokeh-0.7.1-setup.patch b/dev-python/bokeh/files/bokeh-0.7.1-setup.patch
new file mode 100644
index 000000000000..39ea156cc3b7
--- /dev/null
+++ b/dev-python/bokeh/files/bokeh-0.7.1-setup.patch
@@ -0,0 +1,17 @@
+Remove inappropriate check for a previous installation.
+
+Original patch for bokek 0.5.0 (0.5.0-setup.patch).
+Ported for bokeh 0.7.1 by Marius Brehler.
+
+http://bugs.gentoo.org/527336
+
+--- setup.py
++++ setup.py.new
+@@ -348,7 +348,6 @@ path = abspath(dirname(__file__))
+ 
+ print()
+ if 'develop' in sys.argv:
+-    check_remove_bokeh_install(site_packages)
+     with open(path_file, "w+") as f:
+         f.write(path)
+     print("Installing Bokeh for development:")
diff --git a/dev-python/bokeh/metadata.xml b/dev-python/bokeh/metadata.xml
new file mode 100644
index 000000000000..e88bff661521
--- /dev/null
+++ b/dev-python/bokeh/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>sci</herd>
+  <longdescription lang="en">
+  Bokeh is a Python interactive visualization library for large
+  datasets that natively uses the latest web technologies. Its goal is
+  to provide elegant, concise construction of novel graphics in the
+  style of Protovis/D3, while delivering high-performance
+  interactivity over large data to thin clients.
+</longdescription>
+  <upstream>
+    <remote-id type="pypi">bokeh</remote-id>
+    <remote-id type="github">ContinuumIO/bokeh</remote-id>
+  </upstream>
+</pkgmetadata>