2 files changed, 64 insertions, 0 deletions
diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
index 06b1e86b2059..e4f7d01b2aa0 100644
--- a/dev-python/btrfsutil/Manifest
+++ b/dev-python/btrfsutil/Manifest
@@ -1,2 +1,4 @@
 DIST btrfs-progs-v6.12.tar.sign 566 BLAKE2B 3a32b52522acd9e2fcf34cbf90d91ca2491ae1b34142320b987084a60c9f6c13100fcfb554f877c0f659b60415234550c05d980c633015cd8d083df18521187a SHA512 86396dad38f15c19eb4b641632deb99073829896001b71fbdfaa3ebd11468e8b89ed324e563ec9db837c9095501227824f97085347dca4204cbaecceed9da7d3
 DIST btrfs-progs-v6.12.tar.xz 2705336 BLAKE2B d1569ec7b2079a43ac370c3a7e9f1b37a06545675753490f16d6a7bb52281f76df39f924c96569a1c75daa8a998f251c5219e2f09a54cb94c42cba1db3cf43ca SHA512 57da37f460a33b5f5232a5c8e67eb5976fb13483a1437112bd433b179bc0e497a1aadfe24705eb4fb4e0a98d2a33fd3c46808b3ca161421475442a70b964c446
+DIST btrfs-progs-v6.13.tar.sign 566 BLAKE2B 12424d4f076a0b1e007f367c803c0308c45632475dfff56d6f2feb65ad8c84568609554f2870f5ccb2d1ca1559661a811a96c4f5e1ad4744d4c8d14c9e002d5b SHA512 f4423a607dd7a8e0a6d6da9a5ebc9c1147026b25786cb3fd947243491e17730994d74c1885cef5737380a9441a736ee252229951e298e2559a279e16fc18a53b
+DIST btrfs-progs-v6.13.tar.xz 2731048 BLAKE2B aaf536e17977c052dd0828501f5a91b85403d561301f10d8c7bf2f5abae30a323f781ef8727f8ca48efc6edf16000b3ee8435fd6a89d6d047dda289ad87e3f64 SHA512 c91e99beb554320e75bcef027ae918993ed8e08a5fe774ff55bf63cde2c64802676c8678ff09d2678aa084166f178efd2b64ed00821d0908a1435e9eaea74422
diff --git a/dev-python/btrfsutil/btrfsutil-6.13.ebuild b/dev-python/btrfsutil/btrfsutil-6.13.ebuild
new file mode 100644
index 000000000000..09a11b13f573
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.13.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	# Upstream sign the decompressed .tar
+	if use verify-sig; then
+		einfo "Unpacking ${MY_P}.tar.xz ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -xf -))
+		assert "Unpack failed"
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	cat <<-EOF > version.py || die
+	#!/usr/bin/env python3
+	btrfs_util_py_version = '${PV}'
+	EOF
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	rm "${ED}"/usr/share/doc/${PF}/README.md || die
+	dodoc "${S}"/../README.md
+}