3 files changed, 1 insertions, 148 deletions
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 87cb873312c1..514d0c07ac7e 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,6 +1,5 @@
 DIST ipython-9.10.0.tar.gz 4426526 BLAKE2B 0b7e4f370bce45fe9703ae27872217e4a04cca89880863e61499c7132a42c4b739c54202fead6e76c4550408f3555c5b677f4d2dadc93395efbeef7418b3ae3c SHA512 f0f6592aa7984cbf77b82630ec6c9e5d269e6c2486dc885de4640e5d3f60a4d39fb8660a7d7e93efc241ad213a70667322d05a0d86468d22b701698a3e2fb03a
 DIST ipython-9.10.0.tar.gz.provenance 9575 BLAKE2B 2041c8b06c8e896ccb6e6c0fcea9c3708229b35472dec88f3d00b4445095b5e804d48e88357608ea951ae795b37e2007e0f51aaf26b66ef7923dd6ead6fe0935 SHA512 ab56e0f6897fdf00c2d18e630a48ddaec3caeb4670690c8c7607d4384e42fe841e37d644cb68a7c9875620bf40c23590d41409fc92eda0e1ec415b61c69b6435
-DIST ipython-9.4.0.tar.gz 4385338 BLAKE2B 20bf17c945ab2c727aa340a500e2f452dadd440ff809e5aea2ebaa0bd146a6bf2103f2435549a0f4b898690e6aceb15850fc2ba92bb9b94d8e084b1f13cb17a1 SHA512 8e0bd35effa6b5d6d17b7903ae708f1db753717b2271c79b6662fc508e003a7b3b510604ed340e6e89a8c84abf7c3718f785eb39d0914b653c47adc999a1d2f4
 DIST ipython-9.7.0.tar.gz 4422115 BLAKE2B c79ed9d48daa647d3430f8f8a6cb7ea58be3bf9f283be0fb0a68bc530859db5f9cfd8419cef8c783ac7ae939fc111dd4a01841fa22f544135cda536100afbc6c SHA512 d611bd9c36a7497c4757895a074d89ef1bb0ac8def6c819bbe084879f6d44f506a5fa30bddff2249b5e0bb363206eb09b3e311037643ce8f17012513a2285e9f
 DIST ipython-9.8.0.tar.gz 4424940 BLAKE2B 8b4d5673be8e4164a06afe15b6f277d94c0f7196c81c2a2a6195732d0d0f3c353ad9d78c5702ef93edbd1dd44f732332afcfdaa10a2377f2ec9f47318e41b14a SHA512 1f7be5df369ff9c8a5905529286d59927775b47766f6a61ad97f062fb8a068aa9875610e5b313207bf26013ac4dc6d2b24d4d28c3b54586e1f08193d980a6eba
 DIST ipython-9.8.0.tar.gz.provenance 9236 BLAKE2B ca790e6cb3f0bd3e16e319e6283bdf3f36926a5b8238fdfe02057fe6f6254a549398f5109987e90f8179ba9c39c18e8a4dd029c9612801122f68e30d02cd5bc2 SHA512 26d9183e825e2fbc6fe98669e9ae63fe7652fa00e6b927811c438fc7bb5b4b857a9a7d1ba8fc59201de51087726344193962319da91e4aa0c93fcb907f8b655f
diff --git a/dev-python/ipython/ipython-9.4.0.ebuild b/dev-python/ipython/ipython-9.4.0.ebuild
deleted file mode 100644
index bc467e4f4930..000000000000
--- a/dev-python/ipython/ipython-9.4.0.ebuild
+++ /dev/null
@@ -1,146 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
-PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
-
-inherit distutils-r1 optfeature pypi virtualx
-
-DESCRIPTION="Advanced interactive shell for Python"
-HOMEPAGE="
-	https://ipython.org/
-	https://github.com/ipython/ipython/
-	https://pypi.org/project/ipython/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
-IUSE="examples gui notebook nbconvert +smp test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/decorator[${PYTHON_USEDEP}]
-	dev-python/ipython-pygments-lexers[${PYTHON_USEDEP}]
-	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
-	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
-	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
-	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
-	dev-python/stack-data[${PYTHON_USEDEP}]
-	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/typing-extensions[${PYTHON_USEDEP}]
-	' 3.11)
-"
-
-BDEPEND="
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	test? (
-		app-text/dvipng[truetype]
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		>=dev-python/matplotlib-3.9[${PYTHON_USEDEP}]
-		dev-python/nbformat[${PYTHON_USEDEP}]
-		>=dev-python/numpy-1.23[${PYTHON_USEDEP}]
-		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
-		dev-python/packaging[${PYTHON_USEDEP}]
-		dev-python/pickleshare[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/testpath[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-asyncio )
-distutils_enable_tests pytest
-
-RDEPEND+="
-	nbconvert? (
-		dev-python/nbconvert[${PYTHON_USEDEP}]
-	)
-"
-PDEPEND="
-	$(python_gen_cond_dep '
-		gui? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
-	' 'python*')
-	$(python_gen_cond_dep '
-		notebook? (
-			dev-python/notebook[${PYTHON_USEDEP}]
-			dev-python/ipywidgets[${PYTHON_USEDEP}]
-			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
-		)
-	' 3.{11..12})
-	smp? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
-	)
-"
-
-python_prepare_all() {
-	# Rename the test directory to reduce sys.path pollution
-	# https://github.com/ipython/ipython/issues/12892
-	mv IPython/extensions/{,ipython_}tests || die
-
-	distutils-r1_python_prepare_all
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
-	local EPYTEST_DESELECT=()
-
-	case ${EPYTHON} in
-		pypy3*)
-			EPYTEST_DESELECT+=(
-				# https://github.com/ipython/ipython/issues/14244
-				tests/test_display.py::TestAudioDataWithoutNumpy
-			)
-			;;
-	esac
-
-	# nonfatal implied by virtx
-	nonfatal epytest || die "Tests failed on ${EPYTHON}"
-}
-
-python_install() {
-	distutils-r1_python_install
-
-	# Create ipythonX.Y symlinks.
-	# TODO:
-	# 1. do we want them for pypy? No.  pypy has no numpy
-	# 2. handle it in the eclass instead (use _python_ln_rel).
-	# With pypy not an option the dosym becomes unconditional
-	dosym ../lib/python-exec/${EPYTHON}/ipython \
-		/usr/bin/ipython${EPYTHON#python}
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}
-
-pkg_postinst() {
-	optfeature "code formatting" dev-python/black
-	optfeature "sympyprinting" dev-python/sympy
-	optfeature "cythonmagic" dev-python/cython
-	optfeature "%lprun magic command" dev-python/line-profiler
-	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
-
-	if use nbconvert; then
-		if ! has_version virtual/pandoc ; then
-			einfo "Node.js will be used to convert notebooks to other formats"
-			einfo "like HTML. Support for that is still experimental. If you"
-			einfo "encounter any problems, please use app-text/pandoc instead."
-		fi
-	fi
-}
diff --git a/dev-python/ipython/ipython-9.7.0.ebuild b/dev-python/ipython/ipython-9.7.0.ebuild
index aefa39b449bc..b85b375eb19e 100644
--- a/dev-python/ipython/ipython-9.7.0.ebuild
+++ b/dev-python/ipython/ipython-9.7.0.ebuild
@@ -18,7 +18,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="examples gui notebook nbconvert +smp test"
 RESTRICT="!test? ( test )"