1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/pycares/pycares-5.0.0.ebuild b/dev-python/pycares/pycares-5.0.0.ebuild
new file mode 100644
index 000000000000..c1d001bbe023
--- /dev/null
+++ b/dev-python/pycares/pycares-5.0.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python interface for c-ares"
+HOMEPAGE="
+	https://github.com/saghul/pycares/
+	https://pypi.org/project/pycares/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+# Tests fail with network-sandbox, since they try to resolve google.com
+PROPERTIES="test_network"
+RESTRICT="test"
+
+DEPEND="
+	net-dns/c-ares:=
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/cffi[${PYTHON_USEDEP}]
+	' 'python*')
+"
+RDEPEND="
+	dev-python/idna[${PYTHON_USEDEP}]
+	${DEPEND}
+	${BDEPEND}
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+export PYCARES_USE_SYSTEM_LIB=1
+
+EPYTEST_DESELECT=(
+	# https://github.com/saghul/pycares/issues/287
+	# looks like forgotten to update the expected class
+	tests/test_all.py::DNSTest::test_idna2008_encoding
+)