1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/tree-sitter/tree-sitter-0.20.0.ebuild b/dev-python/tree-sitter/tree-sitter-0.20.0.ebuild
new file mode 100644
index 000000000000..544fbb9e087e
--- /dev/null
+++ b/dev-python/tree-sitter/tree-sitter-0.20.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+EGIT_COMMIT="4f39f6919ca3be8efb420a338fd2cf9b8b68b156"
+MY_P=py-tree-sitter-${EGIT_COMMIT}
+FIXTURE_PV=0.19.0
+
+DESCRIPTION="Python bindings to the Tree-sitter parsing library"
+HOMEPAGE="https://github.com/tree-sitter/py-tree-sitter/"
+SRC_URI="
+	https://github.com/tree-sitter/py-tree-sitter/archive/${EGIT_COMMIT}.tar.gz
+		-> ${MY_P}.tar.gz
+	test? (
+		https://github.com/tree-sitter/tree-sitter-javascript/archive/v${FIXTURE_PV}.tar.gz
+			-> tree-sitter-javascript-${FIXTURE_PV}.tar.gz
+		https://github.com/tree-sitter/tree-sitter-python/archive/v${FIXTURE_PV}.tar.gz
+			-> tree-sitter-python-${FIXTURE_PV}.tar.gz
+	)"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="dev-libs/tree-sitter:="
+DEPEND=${RDEPEND}
+
+distutils_enable_tests setup.py
+
+PATCHES=(
+	"${FILESDIR}"/tree-sitter-0.19.0_p20210506-unbundle.patch
+)
+
+src_unpack() {
+	default
+	rmdir "${S}/tree_sitter/core" || die
+
+	if use test; then
+		mkdir "${S}/tests/fixtures" || die
+		local f
+		for f in tree-sitter-{javascript,python}; do
+			mv "${f}-${FIXTURE_PV}" "${S}/tests/fixtures/${f}" || die
+		done
+	fi
+}