blob: 15a7a663ac92f560fe94765528c21b163a9d3ffb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson systemd udev
DESCRIPTION="A simple jobserver for Gentoo"
HOMEPAGE="https://gitweb.gentoo.org/proj/steve.git/"
SRC_URI="
https://gitweb.gentoo.org/proj/steve.git/snapshot/${P}.tar.bz2
"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64"
DEPEND="
dev-libs/libevent:=
sys-fs/fuse:3=
"
RDEPEND="
${DEPEND}
"
BDEPEND="
virtual/pkgconfig
"
src_install() {
meson_src_install
# TODO: move these to meson
systemd_dounit data/steve.service
newconfd data/steve.confd steve
newinitd data/steve.initd steve
insinto /etc/sandbox.d
newins data/sandbox.conf 90steve
udev_newrules data/steve.udev 90-steve.rules
}
pkg_postinst() {
udev_reload
if ! grep -q -s -R -- '--jobserver-auth=fifo:/dev/steve' "${EROOT}"/etc/portage/make.conf
then
elog "In order to use system-wide steve instance, enable the service:"
elog
elog " systemctl enable steve"
elog " systemctl start steve"
elog
elog "Then add to your make.conf:"
elog
elog ' MAKEFLAGS="--jobserver-auth=fifo:/dev/steve"'
elog ' NINJAOPTS=""'
elog
elog "You can use -l in NINJAOPTS but *do not* use -j, as it disables"
elog "job server support."
fi
}
pkg_postrm() {
udev_reload
}
|
