blob: c80379393b45abb151965731834a67034c111c51 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# These must be bumped together:
# dev-cpp/edencommon
# dev-cpp/fb303
# dev-cpp/fbthrift
# dev-cpp/fizz
# dev-cpp/folly
# dev-cpp/mvfst
# dev-cpp/wangle
# dev-util/watchman
inherit flag-o-matic cmake toolchain-funcs
DESCRIPTION="An open-source C++ library developed and used at Facebook"
HOMEPAGE="https://github.com/facebook/folly"
SRC_URI="https://github.com/facebook/folly/releases/download/v${PV}/${PN}-v${PV}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0/${PV}"
KEYWORDS="amd64 ~arm64 ~ppc64"
IUSE="io-uring llvm-libunwind test"
RESTRICT="!test? ( test )"
RDEPEND="
app-arch/bzip2
app-arch/lz4:=
app-arch/snappy:=
app-arch/xz-utils
app-arch/zstd:=
dev-cpp/fast_float:=
dev-cpp/gflags:=
dev-cpp/glog:=[gflags]
dev-libs/boost:=[context]
dev-libs/double-conversion:=
dev-libs/libaio
dev-libs/libevent:=
dev-libs/libfmt:=
dev-libs/libsodium:=
dev-libs/openssl:=
virtual/zlib:=
llvm-libunwind? ( llvm-runtimes/libunwind:= )
!llvm-libunwind? ( sys-libs/libunwind:= )
io-uring? ( >=sys-libs/liburing-2.10:= )
"
DEPEND="
${RDEPEND}
sys-libs/binutils-libs
test? ( dev-cpp/gtest )
"
PATCHES=(
"${FILESDIR}"/${PN}-2024.11.04.00-musl-fix.patch
)
src_unpack() {
# Workaround for bug #889420
mkdir -p "${S}" || die
cd "${S}" || die
default
}
src_prepare() {
# Folly has no configuration option for disabling io_uring support
# so we need to patch it out.
if use !io-uring; then
eapply "${FILESDIR}"/${PN}-2025.04.14.00-force-liburing-off.patch
eapply "${FILESDIR}"/${PN}-2025.04.14.00-CMake-Avoid-finding-liburing.patch
fi
cmake_src_prepare
}
src_configure() {
# bug #949607
filter-lto
local mycmakeargs=(
-DCMAKE_INSTALL_DIR="$(get_libdir)/cmake/${PN}"
-DLIB_INSTALL_DIR="$(get_libdir)"
-DBUILD_TESTS=$(usex test)
# https://github.com/gentoo/gentoo/pull/29393
-DCMAKE_LIBRARY_ARCHITECTURE=$(usex amd64 x86_64 ${ARCH})
)
# https://github.com/facebook/folly/issues/1984
use arm64 && append-cxxflags "-flax-vector-conversions"
cmake_src_configure
}
src_test() {
CMAKE_SKIP_TESTS=(
# Mysterious "invalid json" failure
io_async_ssl_session_test.SSLSessionTest
singleton_thread_local_test.SingletonThreadLocalDeathTest
# TODO: All SIGSEGV, report upstream!
'concurrency_concurrent_hash_map_test.*'
)
if use arm64; then
CMAKE_SKIP_TESTS+=(
# Tests are flaky/timing dependent on both QEMU chroot and real hardware
io_async_hh_wheel_timer_test.HHWheelTimerTest
# Times out on real hardware
concurrent_skip_list_test.ConcurrentSkipList
futures_retrying_test.RetryingTest.largeRetries
)
fi
if [[ $(tc-get-cxx-stdlib) == libc++ ]]; then
CMAKE_SKIP_TESTS+=(
# Aborts with libc++.
# https://github.com/facebook/folly/issues/2345
buffered_atomic_test.BufferedAtomic.singleThreadUnguardedAccess
)
fi
cmake_src_test
}
|
