blob: 478208ff70772680cbed1360be291c3c47db7b45 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 2011-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake-multilib
DESCRIPTION="Google Logging library"
HOMEPAGE="https://github.com/google/glog"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://github.com/google/glog"
inherit git-r3
else
SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
fi
LICENSE="BSD"
SLOT="0/2"
IUSE="gflags +libunwind llvm-libunwind test"
RESTRICT="!test? ( test )"
RDEPEND="
gflags? ( dev-cpp/gflags:=[${MULTILIB_USEDEP}] )
libunwind? (
llvm-libunwind? ( llvm-runtimes/libunwind:=[${MULTILIB_USEDEP}] )
!llvm-libunwind? ( sys-libs/libunwind:=[${MULTILIB_USEDEP}] )
)
"
DEPEND="
${RDEPEND}
test? ( >=dev-cpp/gtest-1.8.0[${MULTILIB_USEDEP}] )
"
src_configure() {
local mycmakeargs=(
-DBUILD_TESTING=$(usex test ON OFF)
-DWITH_GFLAGS=$(usex gflags ON OFF)
-DWITH_GTEST=$(usex test ON OFF)
-DWITH_UNWIND=$(usex libunwind ON OFF)
)
cmake-multilib_src_configure
}
src_test() {
# Tests have a history of being brittle: bug #863599
CMAKE_SKIP_TESTS=(
logging
stacktrace
symbolize
log_severity_conversion
includes_vlog_is_on
includes_raw_logging
)
cmake-multilib_src_test -j1
}
|
