blob: 617ccdfe2fbf2fb7ee2a4451db85ac7c4d572e7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
|
# Copyright 2023-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{11..14} )
inherit cuda cmake python-any-r1 flag-o-matic toolchain-funcs
DESCRIPTION="CUDA Templates for Linear Algebra Subroutines"
HOMEPAGE="https://github.com/NVIDIA/cutlass"
if [[ "${PV}" == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/NVIDIA/${PN}"
else
SRC_URI="
https://github.com/NVIDIA/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
"
KEYWORDS="~amd64"
fi
LICENSE="BSD"
SLOT="0"
X86_CPU_FEATURES=(
f16c:f16c
)
CPU_FEATURES=( "${X86_CPU_FEATURES[@]/#/cpu_flags_x86_}" )
IUSE="clang-cuda cublas cudnn doc dot examples +headers-only jumbo-build performance profiler test tools ${CPU_FEATURES[*]%:*}"
REQUIRED_USE="
headers-only? (
!examples
!profiler
!test
)
test? (
tools
)
"
RESTRICT="!test? ( test )"
RDEPEND="
dev-util/nvidia-cuda-toolkit:=
"
DEPEND="${RDEPEND}
test? (
${PYTHON_DEPS}
dev-cpp/gtest
cudnn? (
dev-libs/cudnn:=
)
)
tools? (
${PYTHON_DEPS}
)
"
pkg_setup() {
if use test || use tools; then
python-any-r1_pkg_setup
fi
}
src_configure() {
# we can use clang as default
if use clang-cuda && ! tc-is-clang; then
export CC="${CHOST}-clang"
export CXX="${CHOST}-clang++"
else
tc-export CXX CC
fi
cuda_add_sandbox
addpredict "/dev/char/"
local mycmakeargs=(
-DCMAKE_POLICY_DEFAULT_CMP0156="OLD" # cutlass_add_library
-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen="$(usex !doc)"
-DCUTLASS_REVISION="${PVR}"
-DCUTLASS_ENABLE_CUBLAS="$(usex cublas)"
-DCUTLASS_ENABLE_CUDNN="$(usex cudnn)"
-DCUTLASS_ENABLE_EXAMPLES="$(usex examples)"
-DCUTLASS_ENABLE_F16C="$(usex cpu_flags_x86_f16c)"
-DCUTLASS_ENABLE_GTEST_UNIT_TESTS="$(usex test)"
-DCUTLASS_ENABLE_HEADERS_ONLY="$(usex headers-only)"
-DCUTLASS_ENABLE_LIBRARY="$(usex !headers-only)"
-DCUTLASS_ENABLE_PERFORMANCE="$(usex performance)"
-DCUTLASS_ENABLE_PROFILER="$(usex profiler)"
-DCUTLASS_ENABLE_PROFILER_UNIT_TESTS="$(usex test "$(usex profiler)")"
-DCUTLASS_ENABLE_TESTS="$(usex test)"
-DCUTLASS_ENABLE_TOOLS="$(usex tools)"
-DCUTLASS_INSTALL_TESTS="no"
-DCUTLASS_NVCC_ARCHS="${CUDAARCHS:-all-major}"
-DCUTLASS_UNITY_BUILD_ENABLED="$(usex jumbo-build)"
-DCUTLASS_USE_SYSTEM_GOOGLETEST="yes"
-DIMPLICIT_CMAKE_CXX_STANDARD="yes"
)
# clang-cuda needs to filter mfpmath
if use clang-cuda; then
filter-mfpmath sse
filter-mfpmath i386
mycmakeargs+=(
-DCMAKE_CUDA_HOST_COMPILER="${CHOST}-clang++"
)
else
mycmakeargs+=(
-DCMAKE_CUDA_HOST_COMPILER="$(cuda_gccdir)"
)
fi
if use cudnn; then
mycmakeargs+=(
-DCUDNN_INCLUDE_DIR="${CUDNN_PATH:-${ESYSROOT}/opt/cuda}/linux/include"
-DCUDNN_LIBRARY="${CUDNN_PATH:-${ESYSROOT}/opt/cuda}/$(get_libdir)/libcudnn.so"
)
fi
if use doc; then
mycmakeargs+=(
-DCUTLASS_ENABLE_DOXYGEN_DOT="$(usex dot)"
)
fi
if use test; then
mycmakeargs+=(
-DCUTLASS_TEST_LEVEL="0"
)
append-cxxflags -DNDEBUG
fi
cmake_src_configure
}
src_test() {
cuda_add_sandbox -w
local myctestargs=(
)
local CMAKE_SKIP_TESTS=(
"ctest_examples_41_fmha_backward_python$"
)
cmake_src_test -j1
cmake_build test_unit "${myctestargs[@]}" -j1
}
src_install() {
cmake_src_install
rm -r "${ED}/usr/test" || die
}
|
