blob: 625edf4230ee88e79f456baf72dced42230afdab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517="setuptools"
PYTHON_COMPAT=( python3_{11..13} )
inherit distutils-r1
DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients"
HOMEPAGE="
https://authlib.org/
https://github.com/authlib/authlib/
https://pypi.org/project/Authlib/
"
# pypi source distribution excludes the tests
SRC_URI="
https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="django flask jose test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-python/cryptography[${PYTHON_USEDEP}]
django? (
dev-python/django[${PYTHON_USEDEP}]
)
flask? (
dev-python/flask[${PYTHON_USEDEP}]
dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
)
jose? (
>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
)
"
BDEPEND="
test? (
dev-python/anyio[${PYTHON_USEDEP}]
dev-python/cachelib[${PYTHON_USEDEP}]
dev-python/django[${PYTHON_USEDEP}]
dev-python/flask[${PYTHON_USEDEP}]
dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
dev-python/httpx[${PYTHON_USEDEP}]
>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/starlette[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=( pytest-asyncio )
EPYTEST_XDIST=1
distutils_enable_tests pytest
src_prepare() {
distutils-r1_src_prepare
# convert from pycryptodomex to pycryptodome
sed -i -e 's:from Cryptodome:from Crypto:' \
authlib/jose/drafts/_jwe_enc_cryptodome.py || die
}
python_test() {
local -x DJANGO_SETTINGS_MODULE=tests.django_settings
epytest tests/{core,jose,clients,flask}
# TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded yet.
#epytest tests/django
}
|
