blob: 4e1f21b6e802d6279ed094be29daece34009ef0c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FORTRAN_NEEDED=fortran
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=meson-python
PYTHON_COMPAT=( python3_{11..14} )
PYTHON_REQ_USE="threads(+)"
inherit flag-o-matic fortran-2 distutils-r1
DESCRIPTION="Scientific algorithms library for Python"
HOMEPAGE="
https://scipy.org/
https://github.com/scipy/scipy/
https://pypi.org/project/scipy/
"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
# Need submodules, so git for now.
EGIT_REPO_URI="https://github.com/scipy/scipy"
EGIT_BRANCH="maintenance/$(ver_cut 1-2).x"
EGIT_SUBMODULES=( '*' )
else
inherit pypi
# Upstream is often behind with doc updates
DOC_PV=1.16.2
SRC_URI+="
doc? (
https://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html-${DOC_PV}.zip
)
"
if [[ ${PV} != *rc* ]]; then
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
fi
fi
LICENSE="BSD LGPL-2"
SLOT="0"
IUSE="doc +fortran test-rust"
# pythran is needed in both BDEPEND (for /usr/bin/pythran) and in DEPEND
# to actually compile code generated by pythran (headers and such needed).
#
# umfpack is technically optional but it's preferred to have it available.
COMMON_DEPEND="
>=dev-python/numpy-1.23.5:=[lapack,${PYTHON_USEDEP}]
>=media-libs/qhull-2020.2:=
virtual/cblas
>=virtual/lapack-3.8
"
# Only boost.math is used, and meson.build doesn't even look up specific boost modules.
DEPEND="
${COMMON_DEPEND}
>=dev-libs/boost-1.89.0
"
RDEPEND="
${COMMON_DEPEND}
dev-python/pillow[${PYTHON_USEDEP}]
"
DEPEND+="
fortran? (
>=dev-python/pythran-0.16.0[${PYTHON_USEDEP}]
)
"
BDEPEND="
dev-lang/swig
>=dev-python/cython-3.0.8[${PYTHON_USEDEP}]
>=dev-python/meson-python-0.15.0[${PYTHON_USEDEP}]
>=dev-python/pybind11-2.13.2[${PYTHON_USEDEP}]
>=dev-python/pytest-8.0.0[${PYTHON_USEDEP}]
>=dev-build/meson-1.5.0
!kernel_Darwin? ( dev-util/patchelf )
virtual/pkgconfig
doc? ( app-arch/unzip )
fortran? (
>=dev-python/pythran-0.16.0[${PYTHON_USEDEP}]
)
test-rust? (
dev-python/pooch[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=( hypothesis )
EPYTEST_XDIST=1
distutils_enable_tests pytest
src_unpack() {
default
if use doc; then
unzip -qo "${DISTDIR}"/${PN}-html-${DOC_PV}.zip -d html || die
fi
}
src_prepare() {
distutils-r1_src_prepare
# unpin system dependencies
sed -i -e "s@version : '@&>=@" meson.build || die
}
python_configure_all() {
DISTUTILS_ARGS=(
-Dblas=blas
-Dlapack=lapack
-Duse-pythran=$(usex fortran true false)
-Duse-system-libraries=all
)
# https://bugs.gentoo.org/932721
has_version '>=dev-python/numpy-2.0.0' && filter-lto
}
python_test() {
# We run tests in parallel, so avoid having n^2 threads in lapack
# tests.
local -x BLIS_NUM_THREADS=1
local -x MKL_NUM_THREADS=1
local -x OMP_NUM_THREADS=1
local -x OPENBLAS_NUM_THREADS=1
cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
local EPYTEST_DESELECT=(
# Network
scipy/datasets/tests/test_data.py::TestDatasets::test_existence_all
scipy/datasets/tests/test_data.py::TestDatasets::test_ascent
scipy/datasets/tests/test_data.py::TestDatasets::test_face
scipy/datasets/tests/test_data.py::TestDatasets::test_electrocardiogram
# Crashes with assertion, not a regression
# https://github.com/scipy/scipy/issues/19321
scipy/signal/tests/test_signaltools.py::test_lfilter_bad_object
# Awfully slow tests
scipy/interpolate/tests/test_bsplines.py::TestBatch::test_batch
scipy/linalg/tests/test_basic.py::TestLstsq::test_random_complex_exact
scipy/sparse/linalg/_eigen/tests/test_svds.py::test_small_sigma_sparse
# TODO: minor precision errors
'scipy/linalg/tests/test_batch.py::TestBatch::test_solve[float32-bdim2]'
'scipy/linalg/tests/test_batch.py::TestBatch::test_lu_solve[float32-bdim2]'
'scipy/stats/tests/test_continuous.py::TestDistributions::test_funcs[cdf-methods11-x-Normal]['
# Crashes, probably too big
'scipy/interpolate/tests/test_fitpack2.py::TestRectBivariateSpline::test_spline_large_2d_maxit'
)
local EPYTEST_IGNORE=()
if ! has_version -b "dev-python/pooch[${PYTHON_USEDEP}]" ; then
EPYTEST_IGNORE+=(
scipy/datasets/tests/test_data.py
)
fi
if has_version -b "sys-libs/zlib-ng[compat]"; then
EPYTEST_DESELECT+=(
# https://github.com/scipy/scipy/issues/23185
scipy/io/matlab/tests/test_streams.py::TestZlibInputStream::test_all_data_read_bad_checksum
scipy/io/matlab/tests/test_streams.py::TestZlibInputStream::test_all_data_read_overlap
)
fi
# avoid other stuff being multithreaded when using xdist
local -x PYTHON_CPU_COUNT=1
epytest scipy
}
python_install_all() {
use doc && local HTML_DOCS=( "${WORKDIR}"/html/. )
distutils-r1_python_install_all
}
|
