blob: 3a71ff619084851075a46e69ec2e7cb087f7e8ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic optfeature strip-linguas xdg
LANGS="ar ast be bg ca cs de el en_GB es et eu fa fi fr gl he hi hu id it ja kk ko ku lb lt ltg mn nl nn pl pt pt_BR ro ru si sk sl sr sv ta tr uk vi zh_CN ZH_TW"
NOSHORTLANGS="en_GB zh_CN zh_TW"
DESCRIPTION="GTK+ based fast and lightweight IDE"
HOMEPAGE="https://www.geany.org"
if [[ "${PV}" = 9999* ]] ; then
inherit autotools git-r3
EGIT_REPO_URI="https://github.com/geany/geany.git"
else
[[ "${PV}" == *_pre* ]] && inherit autotools
SRC_URI="https://download.geany.org/${P}.tar.bz2"
KEYWORDS="amd64 arm ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
fi
LICENSE="GPL-2+ HPND LGPL-2+ LGPL-2.1+"
SLOT="0"
IUSE="+vte wayland X"
BDEPEND="virtual/pkgconfig"
RDEPEND="
>=dev-libs/glib-2.32:2
>=x11-libs/gtk+-3.24:3[wayland?,X?]
!x11-themes/geany-themes
vte? ( x11-libs/vte:2.91 )
"
DEPEND="
${RDEPEND}
dev-util/intltool
sys-devel/gettext
"
pkg_setup() {
strip-linguas ${LANGS}
}
src_prepare() {
xdg_environment_reset #588570
default
# Syntax highlighting for Portage
sed -i -e "s:*.sh;:*.sh;*.ebuild;*.eclass;:" \
data/filetype_extensions.conf || die
if [[ ${PV} = *_pre* ]] || [[ ${PV} = 9999* ]] ; then
eautoreconf
fi
}
src_configure() {
use X || append-cflags -DGENTOO_GTK_HIDE_X11
use wayland || append-flags -DGENTOO_GTK_HIDE_WAYLAND
local myeconfargs=(
--disable-html-docs
--disable-pdf-docs
--disable-static
$(use_enable vte)
)
econf "${myeconfargs[@]}"
}
src_install() {
emake DESTDIR="${D}" install
find "${ED}" -type f \( -name '*.a' -o -name '*.la' \) -delete || die
}
pkg_preinst() {
xdg_pkg_preinst
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "editing files outside the local filesystem" gnome-base/gvfs
optfeature "opening files from the file browser tab" x11-misc/xdg-utils
}
pkg_postrm() {
xdg_pkg_postrm
}
|
