blob: f6f4b1b8e748fdf32395c49b080b60d4ae2bbe2d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
DESCRIPTION="An extremely configurable ftp client"
HOMEPAGE="https://www.ncftp.com/"
SRC_URI="https://www.ncftp.com/public_ftp/${PN}/${P}-src.tar.gz"
LICENSE="Clarified-Artistic"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos"
IUSE="pch"
DEPEND="
sys-libs/ncurses:=
"
RDEPEND="
${DEPEND}
"
BDEPEND="
virtual/pkgconfig
"
src_prepare() {
default
sed \
-e '/^AR=/d' \
-e 's/STRIP=".*"/STRIP=":"/' \
-e 's/\<AC_LANG\>/_AC_LANG/' \
-i autoconf_local/aclocal.m4 || die
AT_M4DIR=autoconf_local/ eautoreconf
}
src_configure() {
tc-export AR CC
LC_ALL="C" \
LIBS="$( $(tc-getPKG_CONFIG) --libs ncurses)" \
econf \
$(use_enable pch precomp) \
--disable-ccdv \
--disable-universal
}
src_install() {
default
dodoc README.txt doc/*.txt
docinto html
dodoc doc/html/*.html
}
|
