blob: c4c53b95ad39d12eebbbb8edd983fa57b72e69f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GUILE_COMPAT=( 2-2 3-0 )
LUA_COMPAT=( lua5-{1..4} )
PYTHON_COMPAT=( python3_{11..14} )
GENTOO_DEPEND_ON_PERL=no
inherit guile-single lua-single perl-module python-single-r1 cmake xdg
if [[ ${PV} == "9999" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/weechat/weechat.git"
EGIT_MIN_CLONE_TYPE=single
BDEPEND+="
app-arch/libarchive
>=dev-ruby/asciidoctor-1.5.4
"
else
inherit verify-sig
SRC_URI="
https://weechat.org/files/src/${P}.tar.xz
verify-sig? ( https://weechat.org/files/src/${P}.tar.xz.asc )
https://dev.gentoo.org/~eschwartz/distfiles/${CATEGORY}/${PN}/${P}-manpages.tar.xz
"
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/weechat.org.asc
BDEPEND+="verify-sig? ( sec-keys/openpgp-keys-weechat )"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~x64-macos"
fi
DESCRIPTION="Portable and multi-interface IRC client"
HOMEPAGE="https://weechat.org/"
LICENSE="GPL-3+"
SLOT="0/${PV}"
NETWORKS="+irc"
PLUGINS="+alias +buflist +charset +exec +fifo +fset +logger +relay +scripts +spell +trigger +typing +xfer"
# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
# dev-lang/php eclass support is lacking, php plugins don't work. bug #705702
SCRIPT_LANGS="guile lua +perl +python ruby tcl ${GENTOO_PERL_USESTRING}"
LANGS=" cs de es fr hu it ja pl pt pt_BR ru sr tr"
IUSE="doc enchant nls relay-api selinux test +zstd ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
REQUIRED_USE="
enchant? ( spell )
guile? ( ${GUILE_REQUIRED_USE} )
lua? ( ${LUA_REQUIRED_USE} )
python? ( ${PYTHON_REQUIRED_USE} )
test? ( nls )
relay-api? ( relay )
"
RDEPEND="
dev-libs/libgcrypt:0=
net-libs/gnutls:=
sys-libs/ncurses:0=
virtual/zlib:=
net-misc/curl[ssl]
charset? ( virtual/libiconv )
guile? ( ${GUILE_DEPS} )
lua? ( ${LUA_DEPS} )
nls? ( virtual/libintl )
perl? (
${GENTOO_PERL_DEPSTRING}
dev-lang/perl:=
virtual/libcrypt:=
)
python? ( ${PYTHON_DEPS} )
relay-api? ( dev-libs/cJSON )
ruby? (
|| (
dev-lang/ruby:3.3
dev-lang/ruby:3.2
dev-lang/ruby:3.1
)
)
selinux? ( sec-policy/selinux-irc )
spell? (
enchant? ( app-text/enchant:* )
!enchant? ( app-text/aspell )
)
tcl? ( >=dev-lang/tcl-8.4.15:0= )
zstd? ( app-arch/zstd:= )
"
DEPEND="${RDEPEND}
test? ( dev-util/cpputest )
"
BDEPEND+="
virtual/pkgconfig
doc? ( >=dev-ruby/asciidoctor-1.5.4 )
nls? ( >=sys-devel/gettext-0.15 )
"
DOCS="AUTHORS.md CHANGELOG.md CONTRIBUTING.md UPGRADING.md README.md"
RESTRICT="!test? ( test )"
maint_pkg_create() {
pushd "${S}" > /dev/null
local -x BUILD_DIR=${S}-docsonly
local mycmakeargs=(
"${mycmakeargs[@]}"
-DENABLE_HEADLESS=ON
-DENABLE_MAN=ON
)
cmake_src_configure
cmake_build doc/all
local ver=$(git describe --exact-match)
ver=${ver#v}
cd "${BUILD_DIR}"/doc || die
local i
for i in *.en.1; do
mv "${i}" "${i/.en/}" || die
done
mkdir -p "${WORKDIR}"/${P}-manpages || die
cp *.1 "${WORKDIR}"/${P}-manpages/ || die
if [[ -n ${ver} ]]; then
local MY_P="${PN}-${ver}"
local tar="${T}/${MY_P}-manpages.tar.xz"
bsdtar -s "#^#${MY_P}-manpages/#S" -caf "${tar}" *.1 || die
einfo "Packaged tar now available:"
einfo "$(du -b "${tar}")"
fi
popd >/dev/null || die
}
src_unpack() {
if [[ ${PV} = 9999 ]]; then
git-r3_src_unpack
else
use verify-sig && verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.asc}
default
fi
}
pkg_setup() {
use guile && guile-single_pkg_setup
use lua && lua-single_pkg_setup
use python && python-single-r1_pkg_setup
}
src_prepare() {
cmake_src_prepare
use guile && guile_bump_sources
# install only required translations
local i
for i in ${LANGS} ; do
if ! has ${i} ${LINGUAS-${i}} ; then
sed -i \
-e "/${i}.po/d" \
po/CMakeLists.txt || die
fi
done
# install only required documentation ; en always
local j
for i in $(grep -e 'set(.*en.*)$' doc/CMakeLists.txt \
| sed -e 's/.*set(\(\w\+\).*/\1/'); do
for j in $(grep set.${i} doc/CMakeLists.txt \
| sed -e "s/.*${i}\(.*\)).*/\1/" -e 's/ en//'); do
if ! has ${j} ${LINGUAS-${j}} ; then
sed -i \
-e "s/\(set(${i}.*\) ${j}/\1/" \
doc/CMakeLists.txt || die
fi
done
done
# install docs in correct directory
sed -i "s#\${DATAROOTDIR}/doc/\${PROJECT_NAME}#\0-${PVR}/html#" doc/CMakeLists.txt || die
if [[ ${CHOST} == *-darwin* ]]; then
# fix linking error on Darwin
sed -i "s/+ get_config_var('LINKFORSHARED')//" \
cmake/FindPython.cmake || die
# allow to find the plugins by default
sed -i 's/".so,.dll"/".bundle,.so,.dll"/' \
src/core/wee-config.c || die
fi
}
src_configure() {
local mycmakeargs=(
-DLIBDIR="${EPREFIX}/usr/$(get_libdir)"
-DENABLE_JAVASCRIPT=OFF
-DENABLE_LARGEFILE=ON
-DENABLE_NCURSES=ON
-DENABLE_PHP=OFF
-DENABLE_ALIAS=$(usex alias)
-DENABLE_BUFLIST=$(usex buflist)
-DENABLE_CHARSET=$(usex charset)
-DENABLE_DOC=$(usex doc)
# To build complete documentation weechat requires all plugins (except
# javascript) to be enabled. That's impossible since php was dropped in
# net-irc/weechat-3.5.r1.ebuild. bug #705702
# If user chooses to build documentation via -DENABLE_DOC we must force
# building incomplete documentation, for which support was added in 4.0.0
# https://github.com/weechat/weechat/blob/v4.0.0/ReleaseNotes.adoc#documentation
-DENABLE_DOC_INCOMPLETE=ON
-DENABLE_ENCHANT=$(usex enchant)
-DENABLE_EXEC=$(usex exec)
-DENABLE_FIFO=$(usex fifo)
-DENABLE_FSET=$(usex fset)
-DENABLE_GUILE=$(usex guile)
-DENABLE_IRC=$(usex irc)
-DENABLE_LOGGER=$(usex logger)
-DENABLE_LUA=$(usex lua)
-DENABLE_NLS=$(usex nls)
-DENABLE_PERL=$(usex perl)
-DENABLE_PYTHON=$(usex python)
-DENABLE_RELAY=$(usex relay)
-DENABLE_CJSON=$(usex relay-api)
-DENABLE_RUBY=$(usex ruby)
-DENABLE_SCRIPT=$(usex scripts)
-DENABLE_SCRIPTS=$(usex scripts)
-DENABLE_SPELL=$(usex spell)
-DENABLE_TCL=$(usex tcl)
-DENABLE_TESTS=$(usex test)
-DENABLE_TRIGGER=$(usex trigger)
-DENABLE_TYPING=$(usex typing)
-DENABLE_XFER=$(usex xfer)
-DENABLE_ZSTD=$(usex zstd)
)
cmake_src_configure
if [[ ${PV} = 9999 ]]; then
maint_pkg_create
fi
}
src_test() {
if $(locale -a | grep -iq "en_US\.utf.*8"); then
cmake_src_test -V
else
eerror "en_US.UTF-8 locale is required to run ${PN}'s ${FUNCNAME}"
die "required locale missing"
fi
}
src_install() {
cmake_src_install
doman "${WORKDIR}"/${P}-manpages/*.1
use guile && guile_unstrip_ccache
}
|
