blob: a3cad45d0a3e9b581efceda78368c7483f449281 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_OPTIONAL=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )
GENTOO_DEPEND_ON_PERL="no"
inherit autotools distutils-r1 dot-a perl-module
MY_PV="$(ver_cut 1-2)"
DESCRIPTION="Library to support AppArmor userspace utilities"
HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${PV}/+download/apparmor-${PV}.tar.gz"
S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
IUSE="doc +perl +python ${GENTOO_PERL_USESTRING} test"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
RDEPEND="
perl? (
${GENTOO_PERL_DEPSTRING}
dev-lang/perl:=
)
python? (
${PYTHON_DEPS}
)
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-build/autoconf-archive
sys-apps/which
sys-devel/bison
sys-devel/flex
doc? ( dev-lang/perl )
perl? ( dev-lang/swig )
python? (
${PYTHON_DEPS}
${DISTUTILS_DEPS}
dev-lang/swig
)
test? (
dev-util/dejagnu
)
"
src_prepare() {
default
use python && distutils-r1_src_prepare
# We used to rm m4/ but led to this after eautoreconf:
# checking whether the libapparmor man pages should be generated... yes
# ./configure: 5065: PROG_PODCHECKER: not found
# ./configure: 5068: PROG_POD2MAN: not found
# checking whether python bindings are enabled... yes
eautoreconf
}
src_configure() {
lto-guarantee-fat
# Run configure through distutils-r1.eclass. Bug 764779
if use python; then
distutils-r1_src_configure
else
python_configure_all
fi
}
python_configure_all() {
# Fails with reflex/byacc, heavily relies on bisonisms
export LEX=flex
export YACC=yacc.bison
local myeconfargs=(
# Needed for tests, just always install them.
--enable-static
$(use_with perl)
$(use_with python)
)
econf "${myeconfargs[@]}"
}
src_compile() {
emake -C src
emake -C include
use doc && emake -C doc
use perl && emake -C swig/perl
if use python ; then
pushd swig/python > /dev/null || die
emake libapparmor_wrap.c
distutils-r1_src_compile
popd > /dev/null || die
fi
}
src_test() {
# Avoid perl-module_src_test. We also need to avoid running the
# Python tests in the wrong environment here.
mv swig/python/test/test_python.py.in{,.bak} || die
touch swig/python/test/test_python.py.in
default
mv swig/python/test/test_python.py.in{.bak,} || die
if use python ; then
pushd swig/python > /dev/null || die
distutils-r1_src_test
popd > /dev/null || die
fi
}
python_test() {
cd test || die
# Force regeneration wrt the earlier hack we did
touch test_python.py.in || die
# Create test_python.py from test_python.py.in
emake test_python.py
LD_LIBRARY_PATH="${S}/src/.libs:${LD_LIBRARY_PATH}" ${EPYTHON} test_python.py || die
}
src_install() {
emake DESTDIR="${D}" -C src install
emake DESTDIR="${D}" -C include install
use doc && emake DESTDIR="${D}" -C doc install
if use perl ; then
emake DESTDIR="${D}" -C swig/perl install
perl_set_version
insinto "${VENDOR_ARCH}"
doins swig/perl/LibAppArmor.pm
# bug 620886
perl_delete_localpod
perl_fix_packlist
fi
if use python ; then
pushd swig/python > /dev/null || die
distutils-r1_src_install
popd > /dev/null || die
fi
dodoc AUTHORS ChangeLog NEWS README
strip-lto-bytecode
find "${D}" -name '*.la' -delete || die
}
python_install() {
distutils-r1_python_install
python_moduleinto LibAppArmor
python_domodule LibAppArmor.py
}
|
