blob: fa643889bd27ee2c2b80f9a9117a222d37125c35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby32 ruby33 ruby34"
RUBY_FAKEGEM_EXTRADOC="NEWS.md README.md"
RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
inherit ruby-fakegem
DESCRIPTION="nanoc is a simple but very flexible static site generator written in Ruby"
HOMEPAGE="https://nanoc.app/"
SRC_URI="https://github.com/nanoc/nanoc/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~riscv"
IUSE="${IUSE} minimal"
DEPEND+="test? ( app-text/asciidoc app-text/highlight )"
RUBY_S="nanoc-${PV}/nanoc-core"
# clonefile is an optional dependency in the gemspec because it does not
# install on Windows.
ruby_add_rdepend "
|| ( dev-ruby/base64:0.3 dev-ruby/base64:0.2 )
>=dev-ruby/clonefile-0.5.3:0.5
>=dev-ruby/concurrent-ruby-1.1:1
dev-ruby/ddmetrics:1
dev-ruby/ddplugin:1
>=dev-ruby/immutable-ruby-0.1:0
>=dev-ruby/json_schema-0.19:0
>=dev-ruby/memo_wise-1.5:1
dev-ruby/slow_enumerator_tools:1
>=dev-ruby/tty-platform-0.2:0
>=dev-ruby/zeitwerk-2.1:2
"
ruby_add_bdepend "test? (
dev-ruby/bundler
dev-ruby/rspec:3
dev-ruby/rspec-its
dev-ruby/fuubar
dev-ruby/minitest
dev-ruby/timecop
dev-ruby/tty-command
dev-ruby/yard
www-apps/nanoc-spec
)
"
PATCHES=( "${FILESDIR}/${PN}-4.12.2-contracts.patch" )
all_ruby_prepare() {
# Avoid unneeded development dependencies
sed -i -e '/simplecov/I s:^:#:' \
-e '/codecov/I s:^:#:' ../common/spec/spec_helper_head_core.rb || die
sed -e '/coverall/I s:^:#:' \
-e '/rubocop/ s:^:#:' \
-i Rakefile || die
sed -i -e '2i require "tmpdir"; require "pathname"' spec/spec_helper.rb || die
echo "-r ./spec/spec_helper.rb" > .rspec || die
sed -i -e "s:require_relative 'lib:require './lib:" ${RUBY_FAKEGEM_GEMSPEC} || die
# Use useable tmp dir
sed -i -e "s:/tmp/whatever:${T}/whatever:" spec/nanoc/core/checksummer_spec.rb || die
# Avoid circular dependency on www-apps/nanoc
sed -i -e '/.all_outdated/,/^ end/ s:^:#:' spec/nanoc/core/feature_spec.rb || die
rm -f spec/nanoc/core_spec.rb || die
# Avoid dependency on unpackaged perfect_toml
rm -f spec/nanoc/core/toml_loader_spec.rb spec/meta_spec.rb || die
sed -e '/can handle TOML/ s/it/xit/' \
-i spec/nanoc/core/structured_data_loader_spec.rb || die
sed -e '/TOML config file present/ s/context/xcontext/' \
-i spec/nanoc/core/config_loader_spec.rb || die
}
each_ruby_test() {
RUBYLIB="${S}/lib" ${RUBY} -S rake spec || die
}
|
