kde-apps/ksystemlog: 22.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-apps/ksystemlog/Manifest b/kde-apps/ksystemlog/Manifest
new file mode 100644
index 00000000000..206bcb6775e
--- /dev/null
+++ b/kde-apps/ksystemlog/Manifest
@@ -0,0 +1 @@
+DIST ksystemlog-22.08.2.tar.xz 1970056 BLAKE2B 602414942406cad2a50483ffaec5820c2980893cef68e49b9f9d02edc44bc7643dee6f1bf735bf2e8adec756471f2d4b5c514c4399b7a7b983c9e042c760f255 SHA512 31c912e853b90c2c855405bb10a970203ed05619319fa855a21e8f61012ae7190cd5abb1edd60f1c746d851385fb4587d6dfdeb0cf8384b02ccfc56f7812d571
diff --git a/kde-apps/ksystemlog/ksystemlog-22.08.2.ebuild b/kde-apps/ksystemlog/ksystemlog-22.08.2.ebuild
new file mode 100644
index 00000000000..9ea6cb71bb4
--- /dev/null
+++ b/kde-apps/ksystemlog/ksystemlog-22.08.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="System log viewer by KDE"
+HOMEPAGE="https://apps.kde.org/ksystemlog/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="audit kdesu systemd"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	audit? ( sys-process/audit )
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}
+	kdesu? ( kde-plasma/kde-cli-tools[kdesu] )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use kdesu; then
+		sed -e "/^X-KDE-SubstituteUID/s:true:false:" \
+			-i src/org.kde.ksystemlog.desktop || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package audit Audit)
+		$(cmake_use_find_package systemd Journald)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	use kdesu || elog "Will show only user readable logs without USE=kdesu (only in X)."
+	use kdesu && elog "Cannot be launched from application menu in Wayland with USE=kdesu."
+}