kde-misc/kweather: 23.04.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/kde-misc/kweather/Manifest b/kde-misc/kweather/Manifest
new file mode 100644
index 00000000000..702f0657d38
--- /dev/null
+++ b/kde-misc/kweather/Manifest
@@ -0,0 +1 @@
+DIST kweather-23.04.2.tar.xz 1018788 BLAKE2B 5d67827a9e7108c4da73cff8fe822a136708df11642078c6374f22088a572a123194396eca867fbd7e964f65090ae7683f72554aa633d31e8ed30c79c6c3a590 SHA512 3c2d574019a0882d1d969e15a8eea9b95af6350e3df9f9b78a0c58778e08c4e5704e11cbec6eb50cd389ca2f3fef47cd4416d487fbc394d2897f6561823cee6a
diff --git a/kde-misc/kweather/kweather-23.04.2.ebuild b/kde-misc/kweather/kweather-23.04.2.ebuild
new file mode 100644
index 00000000000..1fea67873b1
--- /dev/null
+++ b/kde-misc/kweather/kweather-23.04.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="utilities"
+ECM_TEST="false"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Weather forecast application for Plasma with flat and dynamic/animated views"
+HOMEPAGE="https://apps.kde.org/kweather/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~x86"
+
+DEPEND="
+	>=dev-libs/kirigami-addons-0.6:5
+	>=dev-libs/kweathercore-0.6:5
+	>=dev-qt/qtcharts-${QTMIN}:5[qml]
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpositioning-${QTMIN}:5[geoclue]
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	sed -e "/include(ECMCheckOutboundLicense)/s/^/#DONT /" \
+		-e "/ecm_check_outbound_license/s/^/#DONT /" \
+		-i CMakeLists.txt || die # avoid cmake spam about python, reusetool
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PLASMOID=ON
+	)
+	ecm_src_configure
+}