kde-apps/kig: 22.03.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kig/Manifest b/kde-apps/kig/Manifest
index f01be729c5e..6dee4412149 100644
--- a/kde-apps/kig/Manifest
+++ b/kde-apps/kig/Manifest
@@ -1 +1,2 @@
 DIST kig-22.03.80.tar.xz 3175988 BLAKE2B f809384fd23ec09c3a4357810f781a5d87ca9c9fc76e1c12d7dae7830e0612b3dfd54c7fdfc62028abb27168762cfce1dbf6f2da22098c3245d3d0cfdb3ce8fa SHA512 3952aeb6535a84af856e6021289e289b599b234509ac566ab21efce16d1d264b7854e7600e49c6aee0a1e203ba5da878eea9a1e94b7940a1131bf4560d852274
+DIST kig-22.03.90.tar.xz 3184924 BLAKE2B 827a00056403ba6d500c3abefd508f999ee1ea520b1ecb2339b59cdd6bbb8099537f742509e7093c6fe9cc5403e8f36c3e69dfa95e1a3fd5b0f62176ca1491f4 SHA512 1e63ee6336515dcb75ce99377797f457d41434f8c59fb788da73c2981359f2b1c3f475f91c4be06cbddbce128afd7dffeaec6241086a8351842f641a56ff4d06
diff --git a/kde-apps/kig/kig-22.03.90.ebuild b/kde-apps/kig/kig-22.03.90.ebuild
new file mode 100644
index 00000000000..215c8853888
--- /dev/null
+++ b/kde-apps/kig/kig-22.03.90.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.92.0
+QTMIN=5.15.2
+inherit python-single-r1 ecm kde.org
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://apps.kde.org/kig/ https://edu.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="geogebra scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	geogebra? ( >=dev-qt/qtxmlpatterns-${QTMIN}:5 )
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-20.08.70-cmake-boostpython.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package geogebra Qt5XmlPatterns)
+		$(cmake_use_find_package scripting Boost)
+	)
+
+	ecm_src_configure
+}