kde-apps/kaddressbook: 23.03.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kaddressbook/Manifest b/kde-apps/kaddressbook/Manifest
new file mode 100644
index 00000000000..715a169d780
--- /dev/null
+++ b/kde-apps/kaddressbook/Manifest
@@ -0,0 +1 @@
+DIST kaddressbook-23.03.80.tar.xz 3457636 BLAKE2B e6a08053bb7209316f47cc5f4e825f1e55421b1b624a0ff64cc23c6f6d60425815820d192dc398fa9cc2e110b14721c65e1c1b6174d665cb25642757622f40fb SHA512 c7c35d7eda1db1ba31985266abacfe7344172d7e33bf46f7176febe720eeca409d50088c48a67284bc1ec5e40a42e2ae03cfa4c913ff7f4aa587b27df924c543
diff --git a/kde-apps/kaddressbook/kaddressbook-23.03.80.ebuild b/kde-apps/kaddressbook/kaddressbook-23.03.80.ebuild
new file mode 100644
index 00000000000..36c5de30cc8
--- /dev/null
+++ b/kde-apps/kaddressbook/kaddressbook-23.03.80.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.104.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="Address book application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kaddressbook/"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="telemetry"
+
+DEPEND="
+	dev-libs/grantlee:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/akonadi-${PVCUT}:5
+	>=kde-apps/akonadi-contacts-${PVCUT}:5
+	>=kde-apps/akonadi-search-${PVCUT}:5
+	>=kde-apps/grantleetheme-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/libgravatar-${PVCUT}:5
+	>=kde-apps/libkdepim-${PVCUT}:5
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/prison-${KFMIN}:5
+	telemetry? ( >=dev-libs/kuserfeedback-1.2.0:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kdepim-runtime-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Postal addresses" kde-apps/kdepim-addons:${SLOT}
+	fi
+	ecm_pkg_postinst
+}