app-cdr/dolphin-plugins-mountiso: 23.04.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
new file mode 100644
index 00000000000..a705b98ba59
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-23.04.1.tar.xz 272580 BLAKE2B 8f1d898dd218eea4df749bff1825928fed160ed74defee154898ee57f1dc2da4ff8987438c2a49bc658544386c9ccba09a41bff6c6eaed8981baef1084e7b33e SHA512 576abc54f29f06aa2ab0d034161f159302ad33e794a8118b566e940fdea204ed3ca00e71c5dce8dfc23e876370d77e07221feaf67aea1c84ee3e089ab45a46cc
diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-23.04.1.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-23.04.1.ebuild
new file mode 100644
index 00000000000..f4ba6d3d3ef
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-23.04.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.104.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}