kde-apps/konqueror: 20.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 90 insertions, 0 deletions

diff --git a/kde-apps/konqueror/Manifest b/kde-apps/konqueror/Manifest
new file mode 100644
index 00000000000..2c36bbbcfec
--- /dev/null
+++ b/kde-apps/konqueror/Manifest
@@ -0,0 +1 @@
+DIST konqueror-20.12.2.tar.xz 7242304 BLAKE2B 30725fba6991e0fb0f9ea5401e831f42d41e956c971e3554d4600b8b9d675eff92f0d9d49b7e9f9994068d8102ef3a2001e26b5b2b284f335b9f22ba18f3ab49 SHA512 7fddf2bae4d6fd6a88ab4387b64916aab01b61db9e3423a66ac51181c179511e5ff5ba1e6bf21ff78a44207e8bb4a0e03ed9993fc6a3d61bf0c51140a0f6243e
diff --git a/kde-apps/konqueror/konqueror-20.12.2.ebuild b/kde-apps/konqueror/konqueror-20.12.2.ebuild
new file mode 100644
index 00000000000..64777e0e8ce
--- /dev/null
+++ b/kde-apps/konqueror/konqueror-20.12.2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=5.75.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit flag-o-matic ecm kde.org optfeature
+
+DESCRIPTION="Web browser and file manager based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/en/konqueror"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="activities speech X"
+
+# 4 of 4 tests fail. Last checked for 4.0.3
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-apps/kfind:5
+	kde-plasma/kde-cli-tools:5
+"
+
+src_prepare() {
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lmalloc
+
+	ecm_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+		$(cmake_use_find_package X X11)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "bookmarks support" kde-apps/keditbookmarks:${SLOT}
+		optfeature "filemanager component" kde-apps/dolphin:${SLOT}
+		optfeature "SVG support" kde-apps/svg:${SLOT}
+		optfeature "Java support on webpages" virtual/jre
+	fi
+	ecm_pkg_postinst
+}