kde-misc/kdeconnect: 1.4 version bump, update HOMEPAGE, drop ~x86

New dependencies are not keyworded.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 92 insertions, 3 deletions

diff --git a/kde-misc/kdeconnect/Manifest b/kde-misc/kdeconnect/Manifest
new file mode 100644
index 00000000000..33dc860b5e9
--- /dev/null
+++ b/kde-misc/kdeconnect/Manifest
@@ -0,0 +1 @@
+DIST kdeconnect-kde-1.4.tar.xz 389540 BLAKE2B 00a2a20e4a24d74d56db4a812937604d4dd73bc887b262ab967643414f97fcda4e51c54e9f710dc21247c99eec74c3f74eabf3dc2d4c713add6843a2e22e0ff2 SHA512 a8a43327b4185579d626978afc11bb0f334f73f7d68fc72090aab3fd14fb1af381061dd5278fb73e63ff2cb5a688f8ec969c097503d751aff48159237aa56cbf
diff --git a/kde-misc/kdeconnect/kdeconnect-1.4.ebuild b/kde-misc/kdeconnect/kdeconnect-1.4.ebuild
new file mode 100644
index 00000000000..d1b6eefde45
--- /dev/null
+++ b/kde-misc/kdeconnect/kdeconnect-1.4.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KDE_ORG_NAME="${PN}-kde"
+KDE_SELINUX_MODULE="${PN}"
+KFMIN=5.64.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${KDE_ORG_NAME}-${PV}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Adds communication between KDE Plasma and your smartphone"
+HOMEPAGE="https://kde.org/applications/internet/org.kde.kdeconnect.kcm
+https://community.kde.org/KDEConnect"
+
+LICENSE="GPL-2+"
+SLOT="5"
+IUSE="bluetooth pulseaudio wayland X"
+
+DEPEND="
+	>=app-crypt/qca-2.1.0:2[qt5(+),ssl]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpeople-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	bluetooth? ( >=dev-qt/qtbluetooth-${QTMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libfakekey
+		x11-libs/libX11
+		x11-libs/libXtst
+	)
+	pulseaudio? ( media-libs/pulseaudio-qt )
+	wayland? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	dev-libs/kpeoplevcard
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	net-fs/sshfs
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBLUETOOTH_ENABLED=$(usex bluetooth)
+		$(cmake_use_find_package pulseaudio KF5PulseAudioQt)
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X LibFakeKey)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst(){
+	ecm_pkg_postinst
+
+	elog "The Android .apk file is available via"
+	elog "https://play.google.com/store/apps/details?id=org.kde.kdeconnect_tp"
+	elog "or via"
+	elog "https://f-droid.org/repository/browse/?fdid=org.kde.kdeconnect_tp"
+}
diff --git a/kde-misc/kdeconnect/kdeconnect-9999.ebuild b/kde-misc/kdeconnect/kdeconnect-9999.ebuild
index 8fa4e101d9a..d1b6eefde45 100644
--- a/kde-misc/kdeconnect/kdeconnect-9999.ebuild
+++ b/kde-misc/kdeconnect/kdeconnect-9999.ebuild
@@ -12,12 +12,13 @@ QTMIN=5.12.3
 inherit ecm kde.org
 
 if [[ ${KDE_BUILD_TYPE} = release ]]; then
-	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${KDE_ORG_NAME}-${PV}.tar.xz"
-	KEYWORDS="~amd64 ~x86"
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${KDE_ORG_NAME}-${PV}.tar.xz"
+	KEYWORDS="~amd64"
 fi
 
 DESCRIPTION="Adds communication between KDE Plasma and your smartphone"
-HOMEPAGE="https://kde.org/ https://community.kde.org/KDEConnect"
+HOMEPAGE="https://kde.org/applications/internet/org.kde.kdeconnect.kcm
+https://community.kde.org/KDEConnect"
 
 LICENSE="GPL-2+"
 SLOT="5"